跨周期数据转换函数以及跨周期技术指标调用的实现

追涨杀跌

TB的跨周期调用，以前已经有一些解决方案。但总体来说，使用还不够方便。以前的帖子中Nopain曾提出过一个算法，非常精巧。最近在这个算法的基础上， 把整个实现方法完善了一下。下面把总体思路和函数代码贴出来，请大家试用，也欢迎大家提出修改意见。

总体思路：
1、小周期调用大周期的数据；
2、具体方法是新编一个函数，用来根据小周期下的数据推算出大周期的BAR数据，为了省事，计算时，会将大周期下的开高低收以及成交量和持仓量等数据都算出来，然后将这些数据通过引用参数返回。当然有的朋友可能只需要一个收盘价就可以了，那样的话，可以自行修改这个函数，把多余的数据去掉；
3、返回的大周期数据将以序列变量的形式保留在对应的小周期K线上，以便以后调用；
4、另外为了便于大周期的数据计算出来后的回溯使用，函数会将小周期下当前BAR到大周期下的前一个BAR的最后一个小周期BAR需要回溯的BAR数目，作为函数的结果返回。这句话，不容易描述清楚，估计大家听起来也费力，但没关系，后面用例子来解释，知道这回事就行了。
5、另外还增加了一个返回值（也是通过引用参数返回），表示的是当前小周期K线对应的大周期K线在整个大周期中的索引值。举例来说，5分钟图，样本数300，那转换成30分钟周期图，总共应该是50根K线，那最新一根5分钟图对应的30分钟K线在整个30分钟图中的索引值就应该是49（类似CurrentBar 0-49）；

好，其他先不废话，把代码贴出来，再举几个例子。

新建用户函数MtBar, 返回值为数值类型，代码如下：

1. Params
   
2.         Numeric TimeFrame(1440);   
   
3.         // 目标时间周期：月线=40320，周线=10080，日线=1440，4小时线=240
   
4.         // 其他1小时内的周期等于相应的分钟数，如：1小时=60， 30分钟=30。。。
   
5.         // 支持不规则分钟数，如3分钟，8分钟，之类都行
   
6.         
   
7.         Numeric BarsBack(1);
   
8.         // 目标时间周期BAR偏移：
   
9.         // 1--表示将目标时间周期下的前1根K线数据作为与当前Bar对应的目标时间周期下的K线数据
   
10.         // 0--表示将目标时间周期下的截止到目前为止的数据转换为与当前BAR对应的目标时间周期下K线数据
    
11.         
    
12.         NumericRef oCurBar;                 // 目标时间周期下的Bar索引
    
13.         NumericRef oOPenHT;         // 目标时间周期下的开盘价
    
14.         NumericRef oHighHT;         // 目标时间周期下的最高价
    
15.         NumericRef oLowHT;          // 目标时间周期下的最低价
    
16.         NumericRef oCloseHT;        // 目标时间周期下的收盘价
    
17.         NumericRef oVolHT;          // 目标时间周期下的成交量
    
18.         NumericRef oOpenIntHT;      // 目标时间周期下的持仓量
    
19. 
    
20. Vars
    
21.         NumericSeries barCnt;
    
22.         NumericSeries CurBar;
    
23.         NumericSeries barCntSum;
    
24.         NumericSeries OpenHT;
    
25.         NumericSeries HighHT;
    
26.         NumericSeries LowHT;
    
27.         NumericSeries CloseHT;
    
28.         NumericSeries VolHT;
    
29.         NumericSeries OpenIntHT;
    
30.         Numeric CurTime;
    
31.         Numeric PreTime;
    
32.         bool condition(false);
    
33.         Numeric i;
    
34. Begin
    
35.         If (TimeFrame == 40320)                 // 月线
    
36.         {
    
37.                 CurTime = Month;
    
38.                 PreTime = Month[1];
    
39.         }
    
40.         Else If (TimeFrame == 10080)                        // 周线
    
41.         {
    
42.                 CurTime = IntPart(DateDiff(19700105,Date)/7);
    
43.                 PreTime = IntPart(DateDiff(19700105,Date[1])/7);
    
44.         }
    
45.         Else                                                                        // 其他时间周期
    
46.         {
    
47.                 CurTime = IntPart((DateDiff(19700105,date)*1440 + Hour*60 + Minute)/TimeFrame);
    
48.                 PreTime = IntPart((DateDiff(19700105,date[1])*1440 + Hour[1]*60 + Minute[1])/TimeFrame);
    
49.         }
    
50.         condition = CurTime != PreTime;
    
51. 
    
52.         If (CurrentBar==0)                // 如果是第一根Bar, CurBar=0
    
53.         {
    
54.                 barCnt = 0;
    
55.                 CurBar = 0;
    
56.                 OpenHT = Open;
    
57.                 HighHT = High;
    
58.                 LowHT = Low;
    
59.                 CloseHT = Close;
    
60.                 VolHT = Vol;
    
61.                 OpenIntHT = OpenInt;
    
62.         }
    
63.         Else
    
64.         {
    
65.                 If(Condition)               
    
66.                 // 如果在目标周期下，属于另一根K线，则CurBar加1
    
67.                 {
    
68.                         barCnt = 1;
    
69.                         CurBar = CurBar[1] + 1;
    
70.                         OpenHT = Open;
    
71.                         HighHT = High;
    
72.                         LowHT = Low;
    
73.                         VolHT = Vol;
    
74.                 }Else
    
75.                 // 如果在目标周期下，属于同一根K线，则CurBar不变，但最高价和最低价要记录价格的变化，成交量要累加
    
76.                 {
    
77.                         barCnt = barCnt[1] + 1;
    
78.                         CurBar = CurBar[1];
    
79.                         OpenHT = OpenHT[1];
    
80.                         HighHT = Max(HighHT[1],High);
    
81.                         LowHT = Min(LowHT[1],Low);
    
82.                         VolHT = VolHT[1] + Vol;
    
83.                 }
    
84.                 // 收盘价和持仓量总是取最新值
    
85.                 CloseHT = Close;
    
86.                 OpenIntHT = OpenInt;
    
87.         }
    
88.         
    
89.         // 上面的程序，在每根小周期的K线上，记录了它所属的大时间周期下的开高低收等值的变化。
    
90.         // 接下来，要把在大的时间周期级别上，属于同一根K线的开高低收这些数据，记录在这一组小周期K线的最后一根上。
    
91.         barCntSum = barCnt ;
    
92.         If(BarsBack == 0)
    
93.         // 如果Bar偏移参数为0，则取每根小周期K线上保留的大时间周期截止到这根小周期K线为止的BAR数据
    
94.         {
    
95.                 barCntSum = 0 ;
    
96.         }Else If(BarsBack == 1)
    
97.         // 如果Bar偏移参数为1，则取大时间周期的上一根K线的BAr数据
    
98.         {
    
99.                 barCntSum = barCnt ;
    
100.         }Else
     
101.         // 如果BAR偏移参数为其他，则取大时间周期的指定偏移后的那根K线的BAR数据
     
102.         {
     
103.                 For i = 2 To BarsBack
     
104.                 {
     
105.                         barCntSum = barCntSum + barCnt[barCntSum];
     
106.                 }
     
107.         }
     
108. 
     
109.         // 最后将相应的K线数据作为引用参数返回
     
110.         oCurBar = CurBar;
     
111.         oOpenHT = OpenHT[barCntSum];
     
112.         oHighHT = HighHT[barCntSum];
     
113.         oLowHT = LowHT[barCntSum];
     
114.         oCloseHT = CloseHT[barCntSum];
     
115.         oVolHT = VolHT[barCntSum];
     
116.         oOpenIntHT = OpenIntHT[barCntSum];
     
117.         Return barCnt;
     
118. End

复制代码

mengyou

太有用了！感谢楼主分享！！

simonschow

很好的贴子

cutskyck

追涨杀跌 发表于 2011-6-13 01:40
谢谢道勤的鼓励！ 继续把其他几个常用指标的跨周期函数贴出来。
新建MtMacd函数，代码如下： ...

为何在TB极速版里编译结果是：返回值类型与声明类型不匹配呢？  问题在最后一行：return mtBarCnt;

scqh10700621

分钟调用日线似乎会遇到夜盘问题，似乎需要稍加修改。

zhangliang

请教楼主老师，各位大神,请帮忙写一个mtAvgDeviation 跨周期平均背离,谢谢！

clakcenter

太复杂了， SubscribeBar  一个函数解决问题

yeshaolang

Numeric BarsBack(1);
// 后面的代码来看，BarsBack只是设置出来的，不是计算出来的？

If(BarsBack == 0)
        // 如果Bar偏移参数为0，则取每根小周期K线上保留的大时间周期截止到这根小周期K线为止的BAR数据
        {
                barCntSum = 0 ;
        }Else If(BarsBack == 1)
        // 如果Bar偏移参数为1，则取大时间周期的上一根K线的BAr数据
        {
                barCntSum = barCnt ;
        }Else
        // 如果BAR偏移参数为其他，则取大时间周期的指定偏移后的那根K线的BAR数据
        {
                For i = 2 To BarsBack
                {
                        barCntSum = barCntSum + barCnt[barCntSum];
                }
        }

hxd163dzyx

留个脚印

chenxf

追涨杀跌 发表于 2011-6-8 17:51
现在可以举个例子来说明，怎么用上面的几个函数来做交易策略了。假如我们的策略如下：
1、我们以日线的均线 ...

这个跟DataConvert的效果的差异什么？刚接触TB，不太懂这里边的编程逻辑。