跨周期数据转换函数以及跨周期技术指标调用的实现

扶老二

1. //------------------------------------------------------------------------
   
2. // MtParabolicSAR，跨周期抛物线转向ParabolicSAR函数
   
3. // 返回 当前bar的“周期索引”，比如当前在1分钟周期里，折算成15分钟周期的话，从凌晨00:00分钟开始，第1根bar是1，第2根bar是2......第15根bar是15，第16根bar又变成1，......
   
4. // 除了函数本身的返回值，还通过oParCl、oParOpen、oPosition、oTransition这四个引用参数把对应Bar的停损值、对应Bar的停损值下一根的停损值、对应Bar建议的持仓状态（1 - 多头，-1 - 空头）、对应Bar的状态是否发生反转（1 或 -1 为反转，0 为保持不变）
   
5. // 版本 20140511_183500
   
6. //------------------------------------------------------------------------
   
7. 
   
8. Params
   
9.     Numeric TimeFrame(1440);        //目标时间周期参数，参数说明参见MtBar
   
10.     Numeric BarsBack(1);            //目标时间周期BAR偏移参数，说明见MtBar函数
    
11.     Numeric AfStep(0.02);
    
12.     Numeric AfLimit(0.2);
    
13.     NumericRef oParClose;
    
14.     NumericRef oParOpen;
    
15.     NumericRef oPosition;
    
16.     NumericRef oTransition;
    
17. 
    
18. Vars
    
19.     NumericSeries barCnt;
    
20.     NumericSeries CurBar;
    
21.     NumericSeries barCntSum;
    
22.     NumericSeries HighHT;
    
23.     NumericSeries LowHT;
    
24.     Numeric CurTime;
    
25.     Numeric PreTime;
    
26.     bool condition(false);
    
27.     Numeric n;
    
28.     Numeric i;
    
29. 
    
30. 
    
31.     NumericSeries Af(0);   
    
32.     NumericSeries ParOpen(0);
    
33.     NumericSeries ParClose(0);
    
34.     NumericSeries Position(0);  
    
35.     NumericSeries HHValue(0);
    
36.     NumericSeries LLValue(0);
    
37.     NumericSeries Transition(0);
    
38.      
    
39. Begin
    
40.     if(TimeFrame == 40320) {                                        //月线
    
41.         CurTime = Month;
    
42.         PreTime = Month[1];
    
43.     } else if(TimeFrame == 10080) {                                 //周线
    
44.         CurTime = IntPart(DateDiff(19700105, TrueDate(0)) / 7);
    
45.         PreTime = IntPart(DateDiff(19700105, TrueDate(1)) / 7);
    
46.     } else {                                                        //其他时间周期
    
47.         CurTime = IntPart((DateDiff(19700105, TrueDate(0)) * 1440 + Hour * 60 + Minute) / TimeFrame);
    
48.         PreTime = IntPart((DateDiff(19700105, TrueDate(1)) * 1440 + Hour[1] * 60 + Minute[1]) / TimeFrame);
    
49.     }
    
50. 
    
51.     condition = CurTime != PreTime;
    
52. 
    
53.     if(CurrentBar == 0) {                       //如果是第一根Bar, CurBar=0
    
54.         barCnt = 0;
    
55.         CurBar = 0;
    
56.         HighHT = High[1];
    
57.         LowHT = Low[1];
    
58.         
    
59.         Position = 1;
    
60.         Transition = 1;
    
61.         Af = AfStep;
    
62.         HHValue = HighHT;
    
63.         LLValue = LowHT;
    
64.         ParClose = LLValue;
    
65.         ParOpen = ParClose + Af * (HHValue - ParClose);
    
66.         if(ParOpen > LowHT) {
    
67.             ParOpen = LowHT;
    
68.         }
    
69.     } else {
    
70.         if(condition) {                         //如果在目标周期下，属于另一根K线，则CurBar加1
    
71.             barCnt = 1;
    
72.             CurBar = CurBar[1] + 1;
    
73.             HighHT = High[1];
    
74.             LowHT = Low[1];
    
75.             for n = 2 to TimeFrame {
    
76.                 HighHT = Max(HighHT, High[n]);
    
77.                 LowHT = Min(LowHT, Low[n]);
    
78.             }
    
79.         } else {                                //如果在目标周期下，属于同一根K线，则CurBar不变，但最高价和最低价要记录价格的变化，成交量要累加
    
80.             barCnt = barCnt[1] + 1;
    
81.             CurBar = CurBar[1];
    
82.             HighHT = Max(HighHT[1], High);
    
83.             LowHT = Min(LowHT[1], Low);
    
84.         }
    
85.         
    
86.         HHValue = Max(HHValue[1], HighHT);
    
87.         LLValue = Min(LLValue[1], LowHT);
    
88. 
    
89.         if(CurBar == 0) {
    
90.             Position = 1;
    
91.             Transition = 1;
    
92.             Af = AfStep;
    
93.             ParClose = LLValue;
    
94.             ParOpen = ParClose + Af * (HHValue - ParClose);
    
95.             if(ParOpen > LowHT) {
    
96.                 ParOpen = LowHT;
    
97.             }
    
98.         } else {        
    
99.             if(condition) {                       //正好切换到目标周期的下一根k线
    
100.                 Transition = 0;
     
101. 
     
102.                 if(Position[TimeFrame] == 1) {
     
103.                     if(LowHT <= ParOpen[TimeFrame]) {
     
104.                         Position = -1;
     
105.                         Transition = -1;              
     
106.                         ParClose = HHValue;
     
107.                         HHValue = HighHT;
     
108.                         LLValue  = LowHT;
     
109.             
     
110.                         Af = AfStep;
     
111.                         ParOpen = ParClose + Af * (LLValue - ParClose);
     
112.                            
     
113.                         if(ParOpen < HighHT) {
     
114.                             ParOpen = HighHT;
     
115.                         }
     
116.                         
     
117.                         if(ParOpen < HighHT[TimeFrame]) {
     
118.                             ParOpen = HighHT[TimeFrame];
     
119.                         }
     
120.                     } else {
     
121.                         Position = Position[TimeFrame];
     
122.                         ParClose = ParOpen[TimeFrame];                    
     
123.                         if(HHValue > HHValue[TimeFrame] && Af[TimeFrame] < AfLimit) {
     
124.                             if(Af[TimeFrame] + AfStep > AfLimit) {
     
125.                                 Af = AfLimit;
     
126.                             } else {
     
127.                                 Af = Af[TimeFrame] + AfStep;
     
128.                             }               
     
129.                         } else {
     
130.                             Af = Af[TimeFrame];
     
131.                         }   
     
132.                         ParOpen = ParClose + Af * (HHValue - ParClose);               
     
133.             
     
134.                         if(ParOpen > LowHT) {
     
135.                             ParOpen = LowHT;
     
136.                         }
     
137.                         
     
138.                         if(ParOpen > LowHT[TimeFrame]) {
     
139.                             ParOpen = LowHT[TimeFrame];
     
140.                         }
     
141.                     }
     
142.                 } else {
     
143.                     if(HighHT >= ParOpen[TimeFrame]) {
     
144.                         Position = 1;
     
145.                         Transition = 1;
     
146.                         
     
147.                         ParClose = LLValue;
     
148.                         HHValue = HighHT;
     
149.                         LLValue  = LowHT;
     
150.                         
     
151.                         Af = AfStep;
     
152.                         ParOpen = ParClose + Af * (HHValue - ParClose);
     
153.                         if(ParOpen > LowHT) {
     
154.                             ParOpen = LowHT;
     
155.                         }
     
156.                         
     
157.                         if(ParOpen > LowHT[TimeFrame]) {
     
158.                             ParOpen = LowHT[TimeFrame];
     
159.                         }
     
160.                     } else {
     
161.                         Position = Position[TimeFrame];
     
162.                         ParClose = ParOpen[TimeFrame];
     
163.                            
     
164.                         if(LLValue < LLValue[TimeFrame] && Af[TimeFrame] < AfLimit) {
     
165.                             if(Af[TimeFrame] + AfStep > AfLimit) {
     
166.                                 Af = AfLimit;
     
167.                             } else {
     
168.                                 Af = Af[TimeFrame] + AfStep;
     
169.                             }
     
170.                         } else {
     
171.                             Af = Af[TimeFrame];
     
172.                         }
     
173.                         ParOpen = ParClose + Af * (LLValue - ParClose);
     
174.             
     
175.                         if(ParOpen < HighHT) {
     
176.                             ParOpen = HighHT;
     
177.                         }
     
178.                         
     
179.                         if(ParOpen < HighHT[TimeFrame]) {
     
180.                             ParOpen = HighHT[TimeFrame];
     
181.                         }
     
182.                     }
     
183.                 }   
     
184.             }
     
185.         }
     
186.     }
     
187.    
     
188.     //上面的程序，在每根小周期的K线上，记录了它所属的大时间周期下的开高低收等值的变化。
     
189.     //接下来，要把在大的时间周期级别上，属于同一根K线的开高低收这些数据，记录在这一组小周期K线的最后一根上。
     
190.     barCntSum = barCnt;
     
191. 
     
192.     if(BarsBack == 0) {             //如果Bar偏移参数为0，则取每根小周期K线上保留的大时间周期截止到这根小周期K线为止的BAR数据
     
193.         barCntSum = 0;
     
194.     } else if(BarsBack == 1) {      //如果Bar偏移参数为1，则取大时间周期的上一根K线的BAr数据
     
195.         barCntSum = barCnt;
     
196.     } else {                        //如果BAR偏移参数为其他，则取大时间周期的指定偏移后的那根K线的BAR数据
     
197.         for i = 2 to BarsBack {
     
198.             barCntSum = barCntSum + barCnt[barCntSum];
     
199.         }
     
200.     }
     
201. 
     
202.     //最后将相应的K线数据作为引用参数返回
     
203.     oParClose = ParClose[barCntSum];
     
204.     oParOpen = ParOpen[barCntSum];
     
205.     oPosition = Position[barCntSum];
     
206.     oTransition = Transition[barCntSum];
     
207.    
     
208.     Return true;
     
209. End

复制代码

大家一直期待的“MtParabolicSAR，跨周期抛物线转向ParabolicSAR函数”出炉了，有需要的帅哥美女拿去用吧，有问题欢迎交流 QQ: 149561420







上面代码请新建用户函数，取名“MtParabolicSAR”。然后以下是调用示例：

1. Params
   
2. 
   
3. Vars       
   
4.         Numeric oParCl;
   
5.         Numeric oParOp;
   
6.         Numeric oPosition;
   
7.         Numeric oTransition;
   
8.           
   
9. begin
   
10.         MtParabolicSAR(5, 1, 0.02, 0.2, oParCl, oParOp, oPosition, oTransition);
    
11.          
    
12.         Commentary("oParCl:" + Text(oParCl));
    
13.         Commentary("oParOp:" + Text(oParOp));
    
14.         Commentary("oPosition:" + Text(oPosition));
    
15.         Commentary("oTransition:" + Text(oTransition));
    
16. End                     

复制代码

onepiece

很强大

pengpengbird

好贴。

cifco31

追涨杀跌 发表于 2011-6-13 01:57
编译好上面的MtMacd函数后，以后就可以随时通过调用这个函数来显示跨周期的MACD指标，以及在小周期上根据大 ...

      “If (MacdDiff[PreBar]<0 and MacdDiff>0)
        {
                Buy(Lots,Open);
        }
        If (MacdDiff[PreBar]>0 and MacdDiff<0)
        {
                SellShort(Lots,Open);
        }”

这里的MacdDiff[PreBar]>0是什么意思？

santiago

追涨杀跌老师，能否帮助写一下SAR的跨周期指标？最近跟帖在学习，一直没弄明白如何编写SAR的。

扶老二

读书山林 发表于 2011-7-14 13:39
发现一个问题，还请老师帮忙解决一下
   mtBarCnt = MtBar(TimeFrame,BarsBack,refCurBar,refOpen,refHigh, ...

你可以这样子取：

if(BarType == 0) {                          //日线
        BarInterval_ = BarInterval * 1440;
    } else if(BarType == 1) {                   //分钟线
        BarInterval_ = BarInterval;
    } else if(BarType == 4) {                   //周线
        BarInterval_ = BarInterval * 10080;
    } else if(BarType == 5) {                   //月线
        BarInterval_ = BarInterval * 40320;
    }

PlotNumeric("mtClose[10]:", mtClose[10 * TimeFrame / BarInterval_]);

songzantb

收藏，待水平提高后慢慢研究

nh_03600023

http://bbs.tb18.net/thread-29920-2-1.html

woaitbtfx

楼主你好  能否写一下:TICK周期里的行情数据
连续3个TICK主动买单，且买的数量大于50就做多；
连续6个TICK，里面有4个主动买单且数量大于30就做多；

jesonli20