跨周期数据转换函数以及跨周期技术指标调用的实现

追涨杀跌

回复 16# hugh1982

按照你的意思，大致写了一下，看看是否符合你的要求。

1. //------------------------------------------------------------------------
   
2. // 简称: TestMtMa_V2
   
3. // 名称: 周线加日线均线策略
   
4. // 类别: 公式应用
   
5. // 类型: 用户应用
   
6. // 输出:
   
7. //------------------------------------------------------------------------
   
8. 
   
9. Params
   
10.         Numeric TimeFrame(10080);        // 目标时间周期：周线
    
11.         Numeric BarsBack(1);                // 以前一周的均线来判断
    
12. 
    
13.         Numeric WeekLength(5);                // 周线的均线周期               
    
14.         Numeric Length1(5);                        // 日线的短期均线周期
    
15.         Numeric Length2(10);                // 日线的长期均线周期
    
16.         Numeric Lots(1);                        // 交易头寸大小
    
17. Vars
    
18.         NumericSeries WeekMA;
    
19.         Numeric oWeekMA;
    
20. 
    
21.         NumericSeries MA1;
    
22.         NumericSeries MA2;
    
23. Begin
    
24.         MtMa(TimeFrame,BarsBack,WeekLength,oWeekMA);
    
25.         WeekMA = oWeekMA;
    
26.         PlotNumeric("WeekMA",WeekMA);
    
27. 
    
28.         MA1 = AverageFC(Close,Length1);
    
29.         MA2 = AverageFC(Close,Length2);
    
30.         PlotNumeric("MA1",MA1);
    
31.         PlotNumeric("MA2",MA2);
    
32.        
    
33.         If (MA1[1]>WeekMA and MA2[1]>WeekMA)                // 日线短期均线和长期均线均再周线5周期均线之上
    
34.         {
    
35.                 if (MarketPosition!=1 and MA1[1]>MA2[1])
    
36.                 {
    
37.                         Buy(Lots,Open);
    
38.                 }
    
39.                 if (MarketPosition==1 and MA1[1]<MA2[1])
    
40.                 {
    
41.                         Sell(Lots,Open);
    
42.                 }
    
43.         }
    
44.         If (MA1[1]<WeekMA and MA2[1]<WeekMA)                // 日线短期均线和长期均线均再周线5周期均线之下
    
45.         {
    
46.                 if (MarketPosition!=-1 and MA1[1]<MA2[1])
    
47.                 {
    
48.                         SellShort(Lots,Open);
    
49.                 }
    
50.                 if (MarketPosition==-1 and MA1[1]>MA2[1])
    
51.                 {
    
52.                         BuyToCover(Lots,Open);
    
53.                 }
    
54.         }
    
55. End

复制代码

追涨杀跌

Mtma函数的代码，前面已经提供了。你需要依次编译MtBar、MtMa，然后再编译后面的TestMtMa_V2 。

追涨杀跌

拖了好几天了，一直没有把跨周期已经完成的几个指标贴上来。致富网友，也提出了很高的要求，我试着来写一写吧。
首先把跨周期的KDJ指标完成，新建函数MtKDJ，代码如下：

1. Params
   
2.         Numeric TimeFrame(1440);        // 目标时间周期参数，参数说明参见MtBar
   
3.         Numeric BarsBack(1);         // 目标时间周期BAR偏移参数，说明见MtBar函数
   
4.         Numeric Length(14);                       
   
5.         Numeric SlowLength(3);       
   
6.         Numeric SmoothLength(3);
   
7.        
   
8.         NumericRef oKValue;
   
9.         NumericRef oDValue;
   
10. Vars
    
11.         NumericSeries mtBarCnt;
    
12.         NumericSeries mtOpen;
    
13.         NumericSeries mtHigh;
    
14.         NumericSeries mtLow;
    
15.         NumericSeries mtClose;
    
16.         NumericSeries mtVol;
    
17.         NumericSeries mtOpenInt;
    
18.         Numeric refCurBar;
    
19.         Numeric refOpen;
    
20.         Numeric refHigh;
    
21.         Numeric refLow;
    
22.         Numeric refClose;
    
23.         Numeric refVol;
    
24.         Numeric refOpenInt;
    
25. 
    
26.         NumericSeries HighestValue;                               
    
27.         NumericSeries LowestValue;                                       
    
28.         NumericSeries KValue;
    
29.         Numeric DValue;
    
30.         Numeric i;
    
31.         Numeric j(0);
    
32.         Numeric SumHLValue(0);
    
33.         Numeric SumCLValue(0);
    
34.         Numeric sumValue(0);
    
35. 
    
36. Begin
    
37.         mtBarCnt = MtBar(TimeFrame,BarsBack,refCurBar,refOpen,refHigh,refLow,refClose,refVol,refOpenInt);
    
38.         mtHigh = refHigh;
    
39.         mtLow = refLow;
    
40.         mtClose = refClose;
    
41.        
    
42.         HighestValue = mtHigh;
    
43.         LowestValue = mtLow;
    
44.         For i = 1 to Length-1
    
45.         {
    
46.                 j = j + mtBarCnt[j];
    
47.                 If (mtHigh[j] == InvalidNumeric) HighestValue = InvalidNumeric;
    
48.                 Else If ( mtHigh[j] > HighestValue) HighestValue = mtHigh[j];
    
49.                 If (mtLow[j] == InvalidNumeric) LowestValue = InvalidNumeric;
    
50.                 Else If ( mtLow[j] < LowestValue) LowestValue = mtLow[j];
    
51.         }
    
52. 
    
53.         j = 0;
    
54.         For i = 1 to SlowLength
    
55.         {
    
56.                 If (mtClose[j] == InvalidNumeric)
    
57.                 {
    
58.                         SumHLValue = 0;     //InvalidNumeric;
    
59.                         SumCLValue = 0;     //InvalidNumeric;
    
60.                 }
    
61.                 Else
    
62.                 {
    
63.                         SumCLValue = SumCLValue + mtClose[j] - LowestValue[j];
    
64.                         SumHLValue = SumHLValue + HighestValue[j] - LowestValue[j];
    
65.                         j = j + mtBarCnt[j];
    
66.                 }
    
67.         }
    
68. 
    
69.         If (SumHLValue <> 0)
    
70.         {
    
71.                 KValue = SumCLValue/SumHLValue*100;
    
72.         }Else
    
73.         {
    
74.                 KValue = 0;
    
75.         }
    
76. 
    
77.         j = 0;
    
78.         For i = 1 to SmoothLength
    
79.         {
    
80.                 If (KValue[j] == InvalidNumeric) SumValue = 0;     //InvalidNumeric;
    
81.                 Else
    
82.                 {
    
83.                         SumValue = SumValue + KValue[j];
    
84.                         j = j + mtBarCnt[j];
    
85.                 }
    
86.         }
    
87.         DValue = SumValue/SmoothLength;
    
88. 
    
89.         oKValue = KValue;
    
90.         oDValue = DValue;
    
91.         return mtBarCnt;
    
92. End

复制代码

然后和往常一样，写个调用的例子，新建公式应用TestMtKdj，随便在日线以下的时间周期中使用，参数为1440，表示求日线KDJ，根据日线KDJ，金叉买入，死叉卖出，不管交叉发生的位置。代码如下：

1. Params
   
2.         Numeric TimeFrame(1440);        // 日线
   
3.         Numeric BarsBack(1);        // 求前一日的值
   
4.         Numeric Length(14);                       
   
5.         Numeric SlowLength(3);       
   
6.         Numeric SmoothLength(3);
   
7.         Numeric Lots(1);
   
8. Vars
   
9.         NumericSeries KValue;
   
10.         NumericSeries DValue;
    
11.         Numeric ooKValue;
    
12.         Numeric ooDValue;
    
13.         Numeric PreBar;
    
14. Begin
    
15.         PreBar = MtKDJ(TimeFrame,BarsBack,Length,SlowLength,SmoothLength,ooKValue,ooDValue);
    
16.         KValue = ooKValue;
    
17.         DValue = ooDValue;
    
18. 
    
19.         PlotNumeric("K",KValue);
    
20.         PlotNumeric("D",DValue);
    
21.         PlotNumeric("J",3*KValue - 2*DValue);
    
22.         PlotNumeric("Ref1",20);
    
23.         PlotNumeric("Ref2",80);
    
24. 
    
25.         If (KValue[PreBar] < DValue[PreBar] and KValue>DValue)
    
26.         {
    
27.                 Buy(Lots,Open);
    
28.         }
    
29.         If (KValue[PreBar] > DValue[PreBar] and KValue<DValue)
    
30.         {
    
31.                 SellShort(Lots,Open);
    
32.         }
    
33. End

复制代码

追涨杀跌

继续。。。跨周期BOLL线指标，新建函数MtBoll，代码如下：

1. Params
   
2.         Numeric TimeFrame(1440);        // 目标时间周期参数，参数说明参见MtBar
   
3.         Numeric BarsBack(1);         // 目标时间周期BAR偏移参数，说明见MtBar函数
   
4.         Numeric Length(20);                       
   
5.         Numeric Offset(2);
   
6.         NumericRef oUpLine;                        // 上轨
   
7.         NumericRef oDownLine;                // 下轨
   
8.         NumericRef oMidLine;                // 中轨
   
9. Vars
   
10.         NumericSeries mtBarCnt;
    
11.         NumericSeries mtClose;
    
12.         Numeric refCurBar;
    
13.         Numeric refOpen;
    
14.         Numeric refHigh;
    
15.         Numeric refLow;
    
16.         Numeric refClose;
    
17.         Numeric refVol;
    
18.         Numeric refOpenInt;
    
19. 
    
20.         Numeric tempBand;
    
21. 
    
22.         Numeric SumValue(0);
    
23.         Numeric i;
    
24.         Numeric j(0);
    
25.         Numeric SumSqr(0);
    
26.         Numeric VarPSValue;
    
27. 
    
28.        
    
29. Begin
    
30.         mtBarCnt = MtBar(TimeFrame,BarsBack,refCurBar,refOpen,refHigh,refLow,refClose,refVol,refOpenInt);
    
31.         mtClose = refClose;
    
32. 
    
33.         For i = 1 to Length
    
34.         {
    
35.                 If (mtClose[j] == InvalidNumeric) SumValue = InvalidNumeric;
    
36.                 Else
    
37.                 {
    
38.                         SumValue = SumValue + mtClose[j];
    
39.                         j = j + mtBarCnt[j];
    
40.                 }
    
41.         }
    
42. 
    
43.         oMidLine = SumValue/Length;
    
44. 
    
45.         If(Length > 1)
    
46.         {
    
47.                 j = 0;
    
48.                 for i = 0 to Length - 1
    
49.                 {
    
50.                         SumSqr = SumSqr + Sqr( mtClose[j] - oMidLine ) ;
    
51.                         j = j + mtBarCnt[j];
    
52.                 }
    
53.                 VarPSValue = SumSqr / (Length - 1) ;
    
54.         }Else
    
55.         {
    
56.                 VarPSValue = 0;
    
57.         }
    
58. 
    
59.         tempBand = iif(VarPSValue > 0,Sqrt(VarPSValue),0);
    
60. 
    
61.         oUpLine = oMidLine + Offset * tempBand;
    
62.         oDownLine = oMidLine - Offset * tempBand;
    
63.         Return mtBarCnt;
    
64. End

复制代码

再写个公式应用的例子，新建公式应用TestMtBoll，代码如下：

1. Params
   
2.         Numeric TimeFrame(1440);        // 目标时间周期参数，参数说明参见MtBar
   
3.         Numeric BarsBack(1);                 // 目标时间周期BAR偏移参数，说明见MtBar函数
   
4.         Numeric Length(20);                       
   
5.         Numeric Offset(2);
   
6.         Numeric Lots(1);
   
7. Vars
   
8.         NumericSeries UpLine;                        // 上轨
   
9.         NumericSeries DownLine;                        // 下轨
   
10.         NumericSeries MidLine;                        // 中轨
    
11.         NumericSeries PreBar;
    
12.         Numeric UpL;
    
13.         Numeric DnL;
    
14.         Numeric MdL;
    
15. Begin
    
16.         PreBar = MtBOLL(TimeFrame,BarsBack,Length,Offset,UpL,DnL,MdL);
    
17.         UpLine = UpL;
    
18.         DownLine = DnL;
    
19.         MidLine = MdL;
    
20. 
    
21.         PlotNumeric("UpLine",UpLine);
    
22.         PlotNumeric("DownLine",DownLine);
    
23.         PlotNumeric("MidLine",MidLine);
    
24.        
    
25.         If ( MarketPosition != 1 and Close[1]>MidLine[1] and UpLine[1]>UpLine[PreBar] and MidLine[1]>MidLine[PreBar])
    
26.         {
    
27.                 Buy(Lots,Open);
    
28.         }
    
29.         If ( MarketPosition !=-1 and Close[1]<MidLine[1] and DownLine[1]<DownLine[PreBar] and MidLine[1]<MidLine[PreBar])
    
30.         {
    
31.                 SellShort(Lots,Open);
    
32.         }
    
33. End

复制代码

追涨杀跌

最后一个跨周期RSI指标，新建函数MtRSI，代码如下：

1. Params
   
2.         Numeric TimeFrame(1440);        // 目标时间周期参数，参数说明参见MtBar
   
3.         Numeric BarsBack(1);         // 目标时间周期BAR偏移参数，说明见MtBar函数
   
4.         Numeric Length(14) ;
   
5.         NumericRef oRSIValue;
   
6. Vars
   
7.         NumericSeries mtBarCnt;
   
8.         NumericSeries mtClose;
   
9.         Numeric refCurBar;
   
10.         Numeric refOpen;
    
11.         Numeric refHigh;
    
12.         Numeric refLow;
    
13.         Numeric refClose;
    
14.         Numeric refVol;
    
15.         Numeric refOpenInt;
    
16. 
    
17.         NumericSeries NetChgAvg( 0 );
    
18.         NumericSeries TotChgAvg( 0 );
    
19.         Numeric Change( 0 );
    
20.         Numeric SF( 0 );
    
21.         Numeric ChgRatio( 0 ) ;
    
22.         Numeric RSIValue;
    
23.         BoolSeries bStopLoop;
    
24.         Numeric i;
    
25.         Numeric j(0);
    
26.         Numeric K;
    
27.         Numeric nbClose;
    
28.         Numeric nbClose1;
    
29. Begin
    
30.         mtBarCnt = MtBar(TimeFrame,BarsBack,refCurBar,refOpen,refHigh,refLow,refClose,refVol,refOpenInt);
    
31.         mtClose = refClose;
    
32. 
    
33.         SF = 1/Length;
    
34.         bStopLoop = bStopLoop[1];
    
35.         If (bStopLoop!=true)
    
36.         {
    
37.                 j = 0;
    
38.                 For i = 0 to Length
    
39.                 {
    
40.                         If (mtClose[j] == InvalidNumeric)
    
41.                         {
    
42.                                 nbClose = InvalidNumeric;
    
43.                                 i = Length + 1;
    
44.                         }
    
45.                         Else
    
46.                         {
    
47.                                 nbClose = mtClose[j];
    
48.                                 j = j + mtBarCnt[j];
    
49.                         }
    
50.                 }
    
51.                 if(nbClose!=InvalidNumeric and mtClose[j] != InvalidNumeric) bStopLoop = true;
    
52.         }
    
53. 
    
54.         If(nbClose == InvalidNumeric)
    
55.         {
    
56.                 RSIValue = InvalidNumeric;
    
57.         }Else
    
58.         {
    
59.                 If(bStopLoop !=true)
    
60.                 {
    
61.                         NetChgAvg = ( mtClose - nbClose ) / Length ;
    
62.                         j = 0;
    
63.                         K = 0;
    
64.                         For i = 1 To Length
    
65.                         {
    
66.                                 j = K + mtBarCnt[K];
    
67.                                 TotChgAvg = TotChgAvg+Abs(mtClose[K] - mtClose[j]);
    
68.                                 K = j ;
    
69.                         }
    
70.                         TotChgAvg = TotChgAvg / Length;
    
71.                 }
    
72.                 Else
    
73.                 {
    
74.                         Change = mtClose - mtClose[mtBarCnt] ;
    
75.                         NetChgAvg = NetChgAvg[mtBarCnt] + SF * ( Change - NetChgAvg[mtBarCnt] ) ;
    
76.                         TotChgAvg = TotChgAvg[mtBarCnt] + SF * ( Abs( Change ) - TotChgAvg[mtBarCnt] ) ;
    
77.                 }
    
78.                
    
79.                 If( TotChgAvg <> 0 )
    
80.                 {
    
81.                         ChgRatio = NetChgAvg / TotChgAvg ;
    
82.                 }else
    
83.                 {
    
84.                         ChgRatio = 0 ;
    
85.                 }
    
86.                
    
87.                 RSIValue = 50 * ( ChgRatio + 1 ) ;
    
88.         }
    
89.        
    
90.         oRSIValue = RSIValue;
    
91.         return mtBarCnt;
    
92. End

复制代码

再新建公式应用TestMtRsi，把传统的RSI使用方法改了一下，RSI大于50做多，小于50做空。

1. Params
   
2.         Numeric TimeFrame(1440);        // 日线
   
3.         Numeric BarsBack(1);                // 求前一日的值
   
4.         Numeric Length(14) ;
   
5.         Numeric OverSold(30) ;
   
6.         Numeric OverBought(70) ;
   
7.         Numeric Lots(1);
   
8. Vars
   
9.         NumericSeries RSIValue;
   
10.         Numeric oRSIValue;
    
11.         Numeric PreBar;
    
12. Begin
    
13.         PreBar = MtRSI(TimeFrame,BarsBack,Length,oRSIValue);
    
14.         RSIValue = oRSIValue;
    
15. 
    
16.         PlotNumeric("RSI",RSIValue);
    
17.         PlotNumeric("超买",OverBought);
    
18.         PlotNumeric("超卖",OverSold);
    
19. 
    
20.         If (RSIValue>50)
    
21.         {
    
22.                 Buy(Lots,Open);
    
23.         }
    
24.         If (RSIValue<50)
    
25.         {
    
26.                 SellShort(Lots,Open);
    
27.         }
    
28. End

复制代码

追涨杀跌

至此，我已经做好的几个跨周期的指标，已经全部发表完毕。接下来，试着完成致富朋友的要求。其实有了前面的例子，要实现同时读取多个周期的MACD和KDJ值不是什么难事，就是同样的代码复制黏贴，多写几遍就是了。这里我只以MACD为例子，在1分钟图上使用，KDJ的部分致富可以自己完成。计算出来的指标我就不显示了，太多了。我只把提示买入卖出的信息作为注释信息输出了，供你参考吧。

1. Params
   
2.         Numeric FastLength(12);
   
3.         Numeric SlowLength(26);
   
4.         Numeric MACDLength(9);
   
5. Vars
   
6.         Numeric PreBar60;
   
7.         Numeric ooMACDValue60;
   
8.         Numeric ooAvgMACD60;
   
9.         NumericSeries MACDVAlue60;
   
10.         NumericSeries AvgMACD60;
    
11.         NumericSeries MACDDiff60;
    
12.        
    
13.         Numeric PreBar30;
    
14.         Numeric ooMACDValue30;
    
15.         Numeric ooAvgMACD30;
    
16.         NumericSeries MACDVAlue30;
    
17.         NumericSeries AvgMACD30;
    
18.         NumericSeries MACDDiff30;
    
19. 
    
20.         Numeric PreBar15;
    
21.         Numeric ooMACDValue15;
    
22.         Numeric ooAvgMACD15;
    
23.         NumericSeries MACDVAlue15;
    
24.         NumericSeries AvgMACD15;
    
25.         NumericSeries MACDDiff15;
    
26.        
    
27.         Numeric PreBar5;
    
28.         Numeric ooMACDValue5;
    
29.         Numeric ooAvgMACD5;
    
30.         NumericSeries MACDVAlue5;
    
31.         NumericSeries AvgMACD5;
    
32.         NumericSeries MACDDiff5;
    
33. 
    
34.         Numeric PreBar3;
    
35.         Numeric ooMACDValue3;
    
36.         Numeric ooAvgMACD3;
    
37.         NumericSeries MACDVAlue3;
    
38.         NumericSeries AvgMACD3;
    
39.         NumericSeries MACDDiff3;
    
40. 
    
41. Begin
    
42.         PreBar60 = MtMACD(60,1,FastLength,SlowLength,MACDLength,ooMACDValue60,ooAvgMACD60);
    
43.         MACDVAlue60 = ooMACDValue60;
    
44.         AvgMACD60 = ooAvgMACD60;
    
45.         MACDDiff60 = MACDValue60 - AvgMACD60;
    
46. 
    
47.         If (MacdDiff60[PreBar60]<0 and MacdDiff60>0)
    
48.                 Commentary("60分钟MACD买入信号");
    
49.         If (MacdDiff60[PreBar60]>0 and MacdDiff60<0)
    
50.                 Commentary("60分钟MACD卖出信号");
    
51. 
    
52.         PreBar30 = MtMACD(30,1,FastLength,SlowLength,MACDLength,ooMACDValue30,ooAvgMACD30);
    
53.         MACDVAlue30 = ooMACDValue30;
    
54.         AvgMACD30 = ooAvgMACD30;
    
55.         MACDDiff30 = MACDValue30 - AvgMACD30;
    
56. 
    
57.         If (MacdDiff30[PreBar30]<0 and MacdDiff30>0)
    
58.                 Commentary("30分钟MACD买入信号");
    
59.         If (MacdDiff30[PreBar30]>0 and MacdDiff30<0)
    
60.                 Commentary("30分钟MACD卖出信号");
    
61. 
    
62.         PreBar15 = MtMACD(15,1,FastLength,SlowLength,MACDLength,ooMACDValue15,ooAvgMACD15);
    
63.         MACDVAlue15 = ooMACDValue15;
    
64.         AvgMACD15 = ooAvgMACD15;
    
65.         MACDDiff15 = MACDValue15 - AvgMACD15;
    
66. 
    
67.         If (MacdDiff15[PreBar15]<0 and MacdDiff15>0)
    
68.                 Commentary("15分钟MACD买入信号");
    
69.         If (MacdDiff15[PreBar15]>0 and MacdDiff15<0)
    
70.                 Commentary("15分钟MACD卖出信号");
    
71. 
    
72.         PreBar5 = MtMACD(5,1,FastLength,SlowLength,MACDLength,ooMACDValue5,ooAvgMACD5);
    
73.         MACDVAlue5 = ooMACDValue5;
    
74.         AvgMACD5 = ooAvgMACD5;
    
75.         MACDDiff5 = MACDValue5 - AvgMACD5;
    
76. 
    
77.         If (MacdDiff5[PreBar5]<0 and MacdDiff5>0)
    
78.                 Commentary("5分钟MACD买入信号");
    
79.         If (MacdDiff5[PreBar5]>0 and MacdDiff5<0)
    
80.                 Commentary("5分钟MACD卖出信号");
    
81. 
    
82.         PreBar3 = MtMACD(3,1,FastLength,SlowLength,MACDLength,ooMACDValue3,ooAvgMACD3);
    
83.         MACDVAlue3 = ooMACDValue3;
    
84.         AvgMACD3 = ooAvgMACD3;
    
85.         MACDDiff3 = MACDValue3 - AvgMACD3;
    
86. 
    
87.         If (MacdDiff3[PreBar3]<0 and MacdDiff3>0)
    
88.                 Commentary("3分钟MACD买入信号");
    
89.         If (MacdDiff3[PreBar3]>0 and MacdDiff3<0)
    
90.                 Commentary("3分钟MACD卖出信号");
    
91. End

复制代码

追涨杀跌

TB没有在屏幕右上角显示内容的函数。您可以用plotString在当前BAr输出字符串，但要显示您说的那么多，呵呵，恐怕效果非常恐怖。对于程序化交易来说，我倒不认为需要显示那么多指标的信息，直接根据这些信息发出买卖指令不是更直接吗

追涨杀跌

回复 29# haomai01

回haomai01朋友。这两天忙，回复晚了点。其实TB中的ATR指标也是计算了跳空的，您可以仔细看一下指标代码。另外，您希望写的跨周期的ATR指标，我写了一下，供您参考。还是类似的做法，先把计算跨周期ATR的代码写成一个函数MtATR，然后新建一个公式应用调用这个函数显示指标或进行交易。
MtATR代码如下：

1. Params
   
2.         Numeric TimeFrame(1440);        // 目标时间周期参数，参数说明参见MtBar
   
3.         Numeric BarsBack(1);         // 目标时间周期BAR偏移参数，说明见MtBar函数
   
4.         Numeric Length(14);                 // ATR周期
   
5.         NumericRef oATR;                // 目标时间周期下的ATR值
   
6. Vars
   
7.         NumericSeries mtBarCnt;
   
8.         NumericSeries mtCurBar;
   
9.         NumericSeries mtHigh;
   
10.         NumericSeries mtLow;
    
11.         NumericSeries mtClose;
    
12.         Numeric refCurBar;
    
13.         Numeric refOpen;
    
14.         Numeric refHigh;
    
15.         Numeric refLow;
    
16.         Numeric refClose;
    
17.         Numeric refVol;
    
18.         Numeric refOpenInt;
    
19.         NumericSeries TR;
    
20.         Numeric SumValue;
    
21. Begin
    
22.         mtBarCnt = MtBar(TimeFrame,BarsBack,refCurBar,refOpen,refHigh,refLow,refClose,refVol,refOpenInt);
    
23.         mtCurBar = refCurBar;
    
24.         mtHigh = refHigh;
    
25.         mtLow = refLow;
    
26.         mtClose = refClose;
    
27. 
    
28.         if (mtCurBar <= 1) TR = MtHigh - MtLow;
    
29.         else TR = Max(MtHigh,MtClose[mtBarCnt]) - Min(MtLow,MtClose[mtBarCnt]);
    
30. 
    
31.         SumValue = MtSummation(TR,mtBarCnt,Length);
    
32. 
    
33.         oATR = SumValue / Length;
    
34.         return mtBarCnt;
    
35. End

复制代码

公式应用TestMtATR代码如下；

1. Params
   
2.         Numeric TimeFrame(1440);        // 目标时间周期参数，参数说明参见MtBar
   
3.         Numeric BarsBack(1);         // 目标时间周期BAR偏移参数，说明见MtBar函数
   
4.         Numeric Length(14);                 // ATR周期
   
5. Vars
   
6.         NumericSeries ATRValue;
   
7.         Numeric oATR;
   
8. Begin
   
9.         MtATR(TimeFrame,BarsBack,Length,oATR);
   
10.         ATRValue = oATR;
    
11.         PlotNumeric("ATR",ATRValue);
    
12. End

复制代码

追涨杀跌

1、nopain的跨周期例子需要打开不同周期窗口，你的案例主要目的是把大周期固定化，增加数据调用，而且做成用户函数的方式，对吗？

我的目标就是在只开一个小周期窗口的情况下，能通过调用用户函数计算出相应的大周期的数据，然后再根据大周期的数据计算相应的大周期的技术指标，进而根据这些指标值来进行交易。当然由于大周期的滞后性（举例来说，就是当前5分钟线收盘了，但这个5分钟所对应的小时线还不一定收盘了），所以我们函数中，有个参数BarsBack，如果BarsBack=1，就是说计算大周期的K线数据时，用的是当前小周期所对应大周期的前一根K线的值，以5分钟算小时线来举例，10点10分的5分钟线，对应的小时线，为9点开始的小时线。如果BarsBack=2,计算的则是对应大周期的前2根K线的值，还是刚才那个例子，10点10分的5分钟线，对应的小时线，就是前一天的下午2点开始的小时线。如果BarsBack=0，则计算时，大周期的值是到这个小周期线结束时，对应的大周期的K线数据，还举刚才那个例子，10点10分的5分钟线，对应的是10点开始，到10点14分59秒结束时的小时线；10点30分的5分钟线，对应的则是10点开始，到10点34分59秒结束的小时线。

2、关于思路2中，你说用小周期的数据来推算大周期的数据，再用回到小周期里面去。这个目的是什么？是为了实时引用数据吗？比如你后面说的，要在日线是金叉的条件下发生5分钟金叉才会进入市场，而日线金叉也是实时变化的，在未收盘之际，日线发生金叉，5分钟会不会入市？还是5分钟取的是上一日的日线数据？如果是等日线结束或者取上一日的收据，那5分钟入市也没用了。

这就是为了实现很多朋友喜欢的多周期共振系统。以大周期来确定趋势，然后在小周期中寻找合适的进场点。如果BarsBack按照默认值设为1的话，计算的就是上一日的日线数据。这样信号更确定，不会闪烁。确定趋势后，再根据5分钟合适的时机入市，还是有一定意义的，既然是做大趋势，就是要在趋势确定的时候再进场，这并不矛盾。

3、你说的“目标周期”，没有说是大周期还是小周期，不过你赋值的是月线，那就认为是大周期吧。barcnt和curbar是分别指小周期的索引和大周期的索引吗？在2楼的程序里，第75行-83行，说的是月线周期下，如果小周期在大周期里面，则最高最低还有成交量都会受到实时数据的影响，是这个意思吗？但66行-74行我就看不懂了。注释说，“如果在目标周期下，属于另一根K线”，这个是说小周期不在大周期内吗？小周期应该一直都是和大周期同步的啊。比如当前的5分钟K线怎么都是在当前的30分钟之内的啊！

目标周期，就是大周期。先跟您解释一下函数的算法，然后Barcnt和CurBar的意思就能清楚了。在小周期的每根Bar调用函数时，会做一个判断，判断它在大周期上是否是一根新的K线。如果是就是执行66-73行之间的代码，我们还是举例来说，以小周期1分钟大周期5分钟举例，小周期上，9:00, 9:05,9:10。。。。这些时点的1分钟线就属于相应5分钟周期的一根新的K线，所以CurBar要加1，CurBar就是相应的大周期的索引。而9:01,9:06,9:11分。。。这些时点的1分钟线，它和前一个1分钟线，都是属于同一根5分钟线的，所以CurBar保持不变。而Barcnt表示的是从当前小周期的Bar到对应的大周期的Bar需要回溯的BAR数。还是上面的例子，9:00,9:01,9:02,9:03,9:04这五根1分钟K线上面都会计算到自己为止的5分钟的数据，只有9:04分的上面的5分钟数据是真正准确的，所以，9:05的1分钟k线上对应的应该的大周期K线应该是前一个5分钟线也就是9:04分计算出来的值，因此，在9:05的1分钟线上只需要回溯1根BAR，依此类推，9:06的1分钟线应该回溯2根，直到9:09分Barcnt变成5，然后9:10的应该读取9:09这根线上的5分钟数据，所以Barcnt=1,以此类推。。。这个确实需要一个图表来说明。改天吧

追涨杀跌

老师，你好，我根据你写的小周期数据换成大周期数据测试了下，编译不通过啊。
  Return barCnt;

显示 Return 语句的返回类型与公式定义的返回类型值类型不符。
请教下，是什么问题啊。

函数的返回值类型为数值型，在模板选择时，选“数值型”