楼主: 小米

TradeBlazer公式入门教程 [复制链接]

Rank: 10Rank: 10Rank: 10

精华
3
UID
5
积分
26572
帖子
12677
主题
49
阅读权限
200
注册时间
2007-7-20
最后登录
2020-10-27
发表于 2007-8-30 17:28:59 |显示全部楼层
TradeBlazer公式入门教程(11)


Step14

TradeBlazer公式包含的公式类型如下:
用户函数    用户字段(暂时未用)    技术指标    K线型态    特征走势    交易指令


用户函数:用户函数是能够通过函数名称进行引用的指令集,它执行一系列操作并返回一个值。您可以在其他任何公式中使用用户函数进行计算;

用户字段:用户字段是TradeBlazer公式为交易开拓者报价类窗体提供的一项数据输出公式,通过用户字段执行一系列语言指令,给报价窗体返回一个特定的显示值;

技术指标:技术指标是基于基础数据,通过一系列的数学运算,在每个Bar返回相应的结果值的一类公式,这些值在图表模块中输出为线条、柱状图、点等表现形式;

K线型态:K线型态是类似于技术指标的一类公式,它主要着重于反映一段K线的特定型态,并通过不同的技术指标的方式输出到图表;

特征走势:特征走势是类似于技术指标的一类公式,它主要着重于反映整个价格曲线的趋势、变化特征,并通过特定的表达方式输出到图表;

交易指令:交易指令是包含买、卖、平仓,头寸,仓位控制的并执行交易指令的一类公式,它主要帮助您将您的交易思想转化为计算机的操作。

通过调用TradeBlazer公式,您可以在交易开拓者中进行技术分析、交易策略优化测试、公式报警、自动交易等操作。


Step15

用户函数

用户函数是可以通过名称进行调用的一组语句的集合,用户函数返回一个值,这个值可以是Numeric,Bool,String三种类型中的任何一种。您可以在需要的任何地方调用用户函数来完成相应的功能。

例如,在TradeBlazer公式中经常使用的一个用户函数Summation,Summation通过输入Price序列数据,以及Length统计周期数,计算Price最近Length周期的和,每次用户需要进行求和计算的时候,都可以调用Summation代替冗长的求和代码,输入参数并获取返回值。

Summation是TradeBlazer公式中一个比较简单的用户函数,TradeBlazer公式提供了上百个内建用户函数,当然,您也可以编写您自己的用户函数。

用户函数通过参数传递输入数据,通过引用参数或返回值传递输出数据,以上例子中的Summation函数,在被调用的时候格式如下:

  1. Value1 = Summation(Close,10);
复制代码


在调用Summation的时候,需要根据定义时候的参数列表和顺序,输入相应的输入参数,有默认值的参数可以省略输入参数。

用户函数在交易开拓者中使用有如下规则:

*支持九种类型的参数定义,支持指定参数默认值;

*支持使用引用参数,可通过引用参数返回多个数据;

*支持六种类型的变量定义,支持指定变量的默认值;

*可以访问行情数据、属性数据;

*必须通过Return返回数据,返回数据类型为三种基本类型之一;

*脚本中的返回数据类型必须和属性界面设置中一致;

*用户函数之间可以相互调用,用户函数自身也可以递归调用;

*用户函数可以根据设置调用部分的系统函数。


用户函数的类型

用户函数按照返回值类型不同可以分为数值型(Numeric),布尔型(Bool),字符串(String)三种基本类型,三种类型用户函数在调用时需要将返回值赋予类型相同的变量。

按照用户函数属性不同,用户函数可以分为内建用户函数和其他用户函数两种,内建用户函数是交易开拓者提供的,用于支持公式系统运行的预置公式,您可以查看和调用内建用户函数,但是不能删除和修改内建公式。

使用内建用户函数
TradeBlazer公式中提供上百个内建用户函数,一部分用户函数提供类似于求和,求平均,求线性回归等算法方面的功能,另外一些函数提供技术分析的一些算法,比如:RSI,CCI,DMI等,这些用户函数用户辅助完成技术分析。

在创建自己的技术分析和交易系统时,如果需要自己写一些算法,您可以首先在用户函数中查找是否有相应的内建用户函数,尽可能的多使用内建用户函数,减少出错的可能。您也可以编写自己的算法,以供在技术分析和交易系统中使用。

用户函数的参数
大部分用户函数都需要接受输入的信息进行计算,这些输入的信息,我们称之为参数。关于用户函数参数的使用详细说明参见参数

如何编写用户函数
一个用户函数由三部分组成,参数定义,变量定义,脚本正文。

语法如下:

  1. Params
  2.     参数定义语句;
  3. Vars
  4.     变量定义语句;
  5. Begin
  6.     脚本正文;
  7. End
复制代码


参数定义和变量定义部分在前面已经详细叙述过,脚本的正文部分将输入参数进行计算,得出函数的返回值,并通过Return返回。

例如,我们以Average为例,Average计算Price在Length周期内的平均值。Average调用Summation求和,并计算平均值,然后返回结果,脚本如下:

  1. Params
  2.     NumericSeries Price(1);
  3.     Numeric Length(10);
  4. Vars
  5.     Numeric AvgValue;
  6. Begin
  7.     AvgValue = Summation(Price, Length) / Length;       
  8.     Return AvgValue;
  9. End
复制代码


对于使用多个输出的情况,即使用引用参数的情况,我们以求N周期最大值为例进行描述,假定我们需要编写一个用户函数,该函数需要求出序列变量Price在最近Length周期内的最大值,并且要求出最大值出现的Bar和当前Bar的偏移值。脚本如下:

  1. Params
  2.     NumericSeries Price(1);
  3.     Numeric Length(10);
  4.     NumericRef HighestBar(0);
  5. Vars
  6.     Numeric MyVal;
  7.     Numeric MyBar;
  8.     Numeric i;
  9. Begin
  10.     MyVal = Price;
  11.     MyBar = 0;
  12.     For i = 1 to Length - 1
  13.     {
  14.             If ( Price[i] > MyVal)
  15.             {
  16.                     MyVal = Price[i];
  17.                     MyBar = i;
  18.             }
  19.     }
  20.     HighestBar = MyBar;
  21.     Return MyVal;
  22. End
复制代码


用户函数的调用

用户函数成功创建之后(编译/保存成功),您可以在其他的用户函数、技术分析、交易指令等公式中调用用户函数,调用用户函数时需要注意保持参数类型的匹配,即用户函数参数的声明数据类型需和调用时传入参数的数据匹配,这是所指的匹配是指基本数据类型:数值型,布尔型,字符串三种类型匹配,并且保持序列参数和传入变量类型的对应。我们可以对用户函数定义为Numeric或者NumericRef的参数使用Numeric类型的变量作为传入参数;但不能将在定义为NumericSeries类型的参数时传入Numeric。具体的对应关系如下表:



对于函数的返回值,您也可以将用户函数的Numeric返回值赋值给NumericSeries或NumericRef变量。即在用户函数的返回值使用时,忽略其扩展数据类型。比如我们在调用Average求平均值时,可以这样调用:

  1. Vars
  2.     Numeric Value1;
  3. Begin
  4.     Value1 = Average(Close,10);
  5.     ...
  6. End
复制代码


我们也可以按照以下方式进行调用:

  1. Vars
  2.     NumericSeries Value1;
  3. Begin
  4.     Value1 = Average(CloseTmp,10);
  5.     ...
  6. End
复制代码


A用户函数调用自身,我们称之为直接递归;A用户函数可以调用B用户函数,同时B用户函数也可以调用A用户函数,对于这种的情况,我们称之为间接递归;

不管是直接递归还是间接递归,用户函数在执行的时候,都可能遇到递归调用没有出口,导致死循环的情况。因此,我们在编写公式的时候,要注意避免使用递归算法,如果一定需要使用递归算法,要注意保证递归算法都有出口。

用默认参数调用用户函数

用户函数在被调用的时候,如果传入的参数和参数的默认值一样,可以省略输出参数,使用默认值来调用用户参数。只能够对排列在后面的那些参数使用默认参数,默认参数的定义参见参数

对于用户函数的直接递归调用,默认参数调用有一些特殊的意义,如下所示,用户函数Fun1:

  1. Params
  2.     NumericSeries Price(1);
  3. Vars
  4.     Numeric CumValue(0);
  5. Begin
  6.     If(CurrentBar == 0)
  7.     {
  8.         CumValue = Price;
  9.     }else
  10.     {
  11.         CumValue = Fun1[1] + Price;
  12.     }
  13.     Return CumValue;
  14. End
复制代码



技术指标Ind1调用Fun1的代码如下:

  1. Value1 = Fun1(Close);
复制代码


以上的用户函数通过默认参数调用Fun1的意思不是调用Fun1(1),而是将Ind1调用Fun1的Close传递下去,即求Fun1(Close)的上一个Bar的值。以上Ind1调用Fun1的计算结果和调用如下的Fun2计算结果一致。

用户函数Fun2:

  1. Params
  2.     NumericSeries Price(1);
  3. Vars
  4.     Numeric CumValue(0);
  5. Begin
  6.     If(CurrentBar == 0)
  7.     {
  8.         CumValue = Price;
  9.     }else
  10.     {
  11.         CumValue = Fun1(Close)[1] + Price;
  12.     }
  13.     Return CumValue;
  14. End
复制代码
附件: 你需要登录才可以下载或查看附件。没有帐号?注册

使用道具 举报

Rank: 10Rank: 10Rank: 10

精华
3
UID
5
积分
26572
帖子
12677
主题
49
阅读权限
200
注册时间
2007-7-20
最后登录
2020-10-27
发表于 2007-9-3 11:21:04 |显示全部楼层
TradeBlazer公式入门教程(12)


Step16

用户字段

用户字段因为暂时还末用到,所以这部分就先跳过不讲了


技术指标

技术指标是最常用的一类公式,它通过计算一系列的数学公式,在每个Bar都返回值,这些值在图表模块中输出为线条、柱状图、点等表现形式,通过分析图形特点、走势和曲线帮助客户分析行情走势,得出合理的交易判断。

当技术指标应用在图表中时,您可以设置技术指标各输出值的表现形式,以及颜色、粗细等,如下图的点,线,柱状图所示:



技术指标的使用规则归纳如下:

     支持三种基本类型的参数定义,支持指定参数默认值;

     不支持使用引用参数;

     支持六种类型的变量定义,支持指定变量的默认值;

     可以访问Data0-Data49个数据源的Bar数据;

     可以访问行情数据、属性数据;

     必须通过PlotNumeric、PlotBool、PlotString返回数据,返回数据类型为三种基本类型的组合;

     可以输出多组数据,通过PlotNumeric、PlotBool、PlotString的第一个参数,即输出名称来区分输出数据;

     可以支持Alert来进行报警;

     技术指标可以调用所有的用户函数进行计算;

     技术指标可以根据设置调用部分的系统函数;

     技术指标在执行时,必须要指定相应的数据源和周期,需要调用历史数据的,只有历史数据存在的情况下才能返回正确的值。

示例,技术指标RSI,脚本如下:

  1. Params
  2.     Numeric Length(14);
  3.     Numeric OverSold(20);
  4.     Numeric OverBought (80);
  5. Vars
  6.     Numeric RSIValue(0);
  7.     Numeric RSIColor(-1);
  8. Begin
  9.     RSIValue = RSI(Close,Length);
  10.     If (RSIValue > OverBought)
  11.     {
  12.         RSIColor = RED;
  13.     }Else If (RSIValue < OverSold)
  14.     {
  15.         RSIColor = CYAN;
  16.     }
  17.     PlotNumeric("RSI1", RSIValue, RSIColor);
  18.     PlotNumeric("超卖", OverSold);
  19.     PlotNumeric("超买", OverBought);
  20.            
  21.     If CrossOver(RSIValue,OverSold)
  22.     {
  23.             Alert("Indicator exiting oversold zone");
  24.     }
  25.     If CrossUnder(RSIValue, OverBought)
  26.     {
  27.             Alert("Indicator exiting overbought zone");
  28.     }
  29. End
复制代码


技术指标RSI调用RSI内建用户函数计算出结果,然后判断其返回值和超买,超卖的关系,设置显示颜色,并产生报警信息。

技术指标在输出数据时,我们是通过输出值的名称来进行识别,名称相同则认为是一个数据,如下的代码,后面语句的输出数据将会覆盖前面语句的输出数据。

  1. PlotNumeric("Test",10);
  2. PlotNumeric("Test",20);
复制代码


最后"Test"输出的数据为20,而不是10。


K线型态

K线型态是另外一种形式的技术分析公式,它对满足设定条件的Bar进行标记,使之醒目,便于客户进行分析。

当K线型态应用在图表中时,您可以设置其输出值的颜色、风格和粗细,如图所示:



K线型态的使用规则归纳如下:

     支持三种基本类型的参数定义,支持指定参数默认值;

     不支持使用引用参数;

     支持六种类型的变量定义,支持指定变量的默认值;

     可以访问Data0-Data49个数据源的Bar数据;

     可以访问行情数据、属性数据;

     必须通过PlotBar返回数据;

     只能输出一组数据,用名称进行区分;

     可以支持Alert来进行报警;

     K线型态可以调用所有的用户函数进行计算;

     K线型态可以根据设置调用部分的系统函数;

     K线型态在执行时,必须要指定相应的数据源和周期,需要调用历史数据的,只有历史数据存在的情况下才能返回正确的值。

示例,K线型态十字星,脚本如下:

  1. Vars
  2.     Bool Condition(False);
  3. Begin
  4.     Condition = (Abs(Close-Open)*10<(High-Low)) And
  5.                 (High <> Close) And (Low <> Close);
  6.     If (Condition)
  7.     {
  8.         PlotBar("SZX",High,Low)
  9.     }
  10. End
复制代码


K线型态十字星判断条件,条件满足的情况下用PlotBar输出信息。

特征走势


特征走势是另外一种形式的技术分析公式,它对满足设定条件的Bar进行标记,使之醒目,便于客户进行分析。特征走势和K线型态有很多相似之处,最大的不同在于,K线型态和特征走势的数据输出方式。

当特征走势应用在图表中时,您可以设置其输出值的表现形式,以及颜色、风格和粗细,如图所示:



特征走势的使用规则归纳如下:

     支持三种基本类型的参数定义,支持指定参数默认值;

     支持使用引用参数;

     支持六种类型的变量定义,支持指定变量的默认值;

     可以访问Data0-Data49个数据源的Bar数据;

     可以访问行情数据、属性数据;

     必须通过PlotNumeric、PlotBool、PlotString返回数据,返回数据类型为三种基本类型的组合;

     只能输出一组数据,用名称进行区分;

     可以支持Alert来进行报警;

     特征走势可以调用所有的用户函数进行计算;

     特征走势可以根据设置调用部分的系统函数;

     特征走势在执行时,必须要指定相应的数据源和周期,需要调用历史数据的,只有历史数据存在的情况下才能返回正确的值。

示例,特征走势创历史新高,脚本如下:

  1. Params
  2.     Numeric Length(5);
  3. Vars
  4.     Bool Condition(False);
  5. Begin
  6.     Condition = (High ==Highest(High,Length)) ;
  7.     If (Condition)
  8.     {
  9.         PlotNumeric("CLSXG",High)
  10.     }
  11. End
复制代码


特征走势创历史新高判断条件,条件满足的情况下用PlotNumeric、PlotBool、PlotString输出信息。

交易指令

TradeBlazer公式提供一种简单的方法表达您的交易思想,那就是使用交易指令,一个简单的交易指令如下:

  1. If (Condition)
  2.     Buy (1,Close);
复制代码


以上的语句表达的意思是:当某些条件满足了,将用当前Bar的收盘价买入1手指定商品。就像您平时通过经纪商进行交易操作一样,TradeBlazer公式提供四个系统函数和现实中的四种交易动作进行对应,如下:



交易指令的使用规则归纳如下:

     支持三种基本类型的参数定义,支持指定参数默认值;

     不支持使用引用参数;

     支持六种类型的变量定义,支持指定变量的默认值;

     可以访问Data0-Data49个数据源的Bar数据;

     可以访问行情数据、属性数据;

     通过Buy、Sell、SellShort和BuyToCover产生交易动作,也可以使用各种内建平仓指令产生交易动作;

     每个交易指令至少包含一个交易动作;

     交易指令可以调用所有的用户函数进行计算;

     交易指令可以根据设置调用部分的系统函数;

     交易指令在执行时,必须要指定相应的数据源和周期,需要调用历史数据的,只有历史数据存在的情况下才能返回正确的值。

示例,交易指令MACD_LE,脚本如下:

  1. Params
  2.     Numeric FastLength( 12 );
  3.     Numeric SlowLength( 26 );
  4.     Numeric MACDLength( 9 );
  5.     Numeric BuyLots(1);
  6. Vars   
  7.     NumericSeries MACDValue;
  8.     NumericSeries AvgMACD;
  9.     Numeric MACDDiff;
  10.     Bool Condition1;
  11.     Bool Condition2;
  12. Begin
  13.     MACDValue = XAverage( Close, FastLength ) -
  14.                     XAverage( Close, SlowLength ) ;       
  15.     AvgMACD = XAverage(MACDValue,MACDLength);
  16.     MACDDiff = MACDValue - AvgMACD;
  17.     Condition1 = CrossOver(MACDValue, AvgMACD) ;
  18.     Condition2 = MACDValue > 0;
  19.     if (Condition1 And Condition2)
  20.     {
  21.         Buy(BuyLots,Close);
  22.     }
  23. End
复制代码


MACD_LE在零轴之上,当MACDValue向上穿过AvgMACD值时为产生多头买入指令。

关于Delay

默认情况下,4个交易函数产生的委托单即时发送;当参数Delay=True时,委托单将延迟到下一个Bar发送,这样设计的原因在于:只有延迟的委托单才会保证发送的交易指令的正确性。

假定在某商品A的周期为5分钟的数据上应用交易指令,A商品每1秒钟会产生一个Tick数据,因此一段时间内(<5分钟)A商品最后一个Bar的数据的收盘价,最高价,最低价以及成交量等数据,会随着Tick的变化和累计而产生相应的变化。在某种情况下,上一个Tick更新时,Buy的预设条件可能为False,下一个Tick更新时,Buy的预设条件为True。如果不延迟,将会马上发送该委托单到交易所。但是,当更多的Tick累计,产生一个新的Bar时,Buy的预设条件可能会变成False。在这种情况,前面产生的委托单将会丢失,不会在测试和优化报表中出现。该委托单实际上是由于噪音数据产生的错误讯号导致,为了避免这种情况的出现,一定要等最后Bar数据更新结束之后,新Bar产生第一个Tick时,才会发送上一个Bar产生的委托单。

当交易函数的延迟设置为False。将会实时发送产生的委托单,按Tick进行更新。在使用该参数时,需要确认自己所编写的公式不会用到这些无效的中间数据,从而影响交易结果。

注意: Delay参数对交易会产生重要的影响,请在确认理解含义之后才进行真实的交易。


关于内建平仓指令

除了上节的Sell和BuyToCover可以进行平仓之外,TradeBlazer公式提供了额外的八种平仓函数,通过合理的应用内建平仓函数,可以帮助您有效的锁定风险并及时获利。

您可以组合使用内建平仓函数,也可以在自己的交易指令中调用内建平仓函数进行平仓,八个内建平仓函数如下:



关于ExitPosition

上述多个平仓函数都用到了参数ExitPosition,作为平仓函数仓位控制的重要参数,有必要对该参数进行单独说明。

ExitPosition是布尔型参数,当ExitPosition=True时,表示将当前所有的持仓作为一个整体,根据其平均建仓成本,计算各平仓函数的盈亏,当条件满足时,会将所有仓位一起平掉;当ExitPosition=False时,表示单独对每个建仓位置进行平仓,单独计算各平仓函数盈亏时,当单个建仓位置条件满足后,平掉该建仓位置即可。

[ 本帖最后由 小米 于 2007-9-3 11:57 编辑 ]
附件: 你需要登录才可以下载或查看附件。没有帐号?注册

使用道具 举报

Rank: 10Rank: 10Rank: 10

精华
3
UID
5
积分
26572
帖子
12677
主题
49
阅读权限
200
注册时间
2007-7-20
最后登录
2020-10-27
发表于 2007-9-3 12:18:59 |显示全部楼层
TradeBlazer公式入门教程(13)


Step17


在技术分析中设置报警

公式报警
TradeBlazer公式提供报警功能,您可以在3类技术分析(技术指标,K线型态,特征走势)中通过Alert函数来实现报警。

您可以在这3类公式中按照以下方式来编写自己的报警:
  1. Vars
  2.     Bool Condition1;
  3. Begin
  4.     Condition1 = 您设定的条件表达式;
  5.     If(AlertEnabled AND Condition1)
  6.     {
  7.         Alert("报警信息...");
  8.     }
  9. End
复制代码
当公式编译保存成功之后,您可以将其应用在超级图表中,通过报警属性页(帮助--公式系统--TradeBlazer公式应用--公式属性)启动报警。当条件满足之后,将会产生报警信息,并发送到消息中心(帮助--系统基础--消息中心)。

Step18

交易策略-完整的交易系统

通常单个交易指令只完成建仓或平仓的单个动作,而一个完整的交易策略应该至少包含建仓、平仓交易指令,并且根据需要加上止损,获利等锁定风险和收益的交易指令。多个交易指令的组合才能更加有效的帮助我们完整的进行交易,因此,我们将多个交易指令的有效组合称之为交易策略。

交易策略的运行机制

假定我们创建一个交易策略,该交易策略由以下交易指令组成,并按照如下顺序应用到超级图表中。



当我们将该交易策略应用到超级图表上时,TradeBlazer公式将会从图表的第一个Bar开始执行交易策略,在第一个Bar上首先执行多头建仓指令A,可能会产生交易委托(开仓),该委托可能被设置为在当前Bar执行,也可以被设置为延迟到下一个Bar执行。当多头建仓指令A执行完成之后,将按顺序调用多头平仓指令B,同时该指令会判断当前的持仓状态,仓位等信息,当条件满足的时候会产生交易委托(平仓)。依次执行止损平仓指令C和获利平仓指令D,当四个交易指令在第一个Bar上都执行完之后,将会移到第二个Bar执行,这时候,系统会首先读取上一个Bar是否有延迟的交易委托,如果有延迟的交易委托,对这些委托先进行处理,然后像第一个Bar一样,依次调用各个交易指令。以此类推,从图表的第一个Bar到最后一个Bar,全部执行完成之后,整个交易策略执行完毕。在整个执行过程产生的所有交易委托被保存下来供超级图表模块显示或进行性能测试分析。

当交易策略应用在超级图表中时,您可以设置交易策略开平仓的显示风格以及颜色、线条等, 使之显示在超级图表中,如下图所示:



交易策略测试引擎

为了真实准确的模拟交易策略在过去时段的表现,并能在实时数据更新时使交易策略沿着预定的方向发展,TradeBlazer公式提供了一个强大的交易策略测试引擎,该处理引擎收集交易策略在历史过程中产生的所有委托单,将其应用在对应的图表中,并能根据交易设置创建交易策略性能测试报表供客户参考。

交易策略测试引擎包括了两大功能:历史数据测试和实时自动交易。历史数据测试分析交易策略在历史过程中的交易动作并计算出交易盈亏,收益等性能指数。实时自动交易收集实时数据,并根据实时数据生成相应的交易动作,条件满足时,将委托单直接发送到交易券商。

[ 本帖最后由 小米 于 2007-9-4 16:40 编辑 ]
附件: 你需要登录才可以下载或查看附件。没有帐号?注册

使用道具 举报

Rank: 10Rank: 10Rank: 10

精华
3
UID
5
积分
26572
帖子
12677
主题
49
阅读权限
200
注册时间
2007-7-20
最后登录
2020-10-27
发表于 2007-9-4 17:12:04 |显示全部楼层
TradeBlazer公式入门教程(14)


Step19


交易策略参数优化

在超级图表中插入一个或一个以上交易指令后,菜单和工具栏中的交易策略参数优化选项将会有效,您可以通过点击菜单项或工具栏使用该功能。

交易策略参数优化模块可对多个交易指令组合的所有参数进行优化,您可以通过参数设置界面对需要优化的参数进行设置,界面如下:



参数优化目标有以下七种选项:

     净利润最大: 以优化结果中的净利润最大为目标,保留指定数量的记录数;

     交易次数最大: 以优化结果中的交易次数最大为目标,保留指定数量的记录数;

     平均净利润最大: 以优化结果中的平均净利润最大为目标,保留指定数量的记录数;

     盈利因子最大: 以优化结果中的盈利因子最大为目标,保留指定数量的记录数;

     收益率最大: 以优化结果中的收益率最大为目标,保留指定数量的记录数;

     盈亏比率最大: 以优化结果中的盈亏比率最大为目标,保留指定数量的记录数;

     回报率最大: 以优化结果中的回报率最大为目标,保留指定数量的记录数。

通过双击参数项或点击参数设置按钮,对选中的参数项进行步长设置,界面如下:



您可以设置参数的最小值,步长及最大值,系统将会根据设置,产生从最小值到最大值之间按步长分布的参数列表。

在各项参数设置完成之后,点击确定按钮,将会进行参数优化的计算,参数优化计算过程中会显示优化的进程,时间,当前参数,最优参数以及优化目标等信息,您可以通过点击取消按钮终止计算。

寻找最优的参数。需防止过度优化。
寻找最稳定的系统。而不是最大化的系统。



注意: 根据优化参数设置的多少,优化时间可能长达几小时甚至数天,优化过程中,CPU将会大量被占用,您可以选择空闲的时间进行大量参数优化计算。


参数优化计算完成之后,将会显示出最优的记录,您可以通过工具栏的交易设置按钮修改交易参数,也可以通过重新优化按钮进行重新计算。

Step20

交易策略性能测试

在超级图表中插入一个或一个以上交易指令后,菜单和工具栏中的交易策略测试报表选项将会有效,您可以通过点击菜单项或工具栏使用该功能。

交易策略测试报表界面如下:



帐户分析按照五个方面对帐户进行分析,包括交易汇总、交易分析、交易记录、平仓分析、阶段总结、资产变化、图表分析和系统设置。

     交易汇总:按照多头交易、空头交易和全部交易列出当前交易策略的交易统计信息。

     交易分析:对当前策略的交易情况进行分析,包括交易分析、盈亏分析和连续盈亏分析。

     交易记录:按开仓平仓对所有交易进行配对组合,并计算盈亏及累计盈亏。

     平仓分析:按平仓记录对交易情况进行分析和汇总。

     阶段总结:按年、月对交易盈亏及次数进行统计。

     资产变化:列出资产的变化记录及统计信息。

     图表分析:按资产图表和盈亏图表两大类共十三小类对帐户进行图表分析。

     系统设置:显示交易策略的参数,设置以及数据等内容。

[ 本帖最后由 小米 于 2007-9-4 17:30 编辑 ]
附件: 你需要登录才可以下载或查看附件。没有帐号?注册

使用道具 举报

Rank: 2

精华
0
UID
992
积分
101
帖子
20
主题
0
阅读权限
30
注册时间
2007-12-28
最后登录
2008-6-18
发表于 2007-12-28 17:23:29 |显示全部楼层
怎么还没有更新呀?我都等不急了!!!
我强烈支持你哟!!!

使用道具 举报

Rank: 4

精华
0
UID
1109
积分
444
帖子
67
主题
25
阅读权限
50
注册时间
2008-1-23
最后登录
2008-7-12
发表于 2008-1-23 21:11:21 |显示全部楼层
玩这个软件还真不简单,难到不怕,没地方学就很担心了。

使用道具 举报

Rank: 5Rank: 5

精华
1
UID
404
积分
1434
帖子
236
主题
74
阅读权限
60
注册时间
2007-9-23
最后登录
2014-7-25
发表于 2008-5-23 13:42:55 |显示全部楼层
可以专门出一本  TB编写教程 ,送给在TB实盘的,也可以卖给在学习的

使用道具 举报

Rank: 2

精华
0
UID
853
积分
79
帖子
13
主题
1
阅读权限
30
注册时间
2007-12-1
最后登录
2010-1-28
发表于 2008-6-3 13:16:55 |显示全部楼层
(忘了不能在该贴下回复了)

[ 本帖最后由 牛在天上飞 于 2008-6-5 09:21 编辑 ]

使用道具 举报

Rank: 1

精华
0
UID
1724
积分
34
帖子
5
主题
1
阅读权限
10
注册时间
2008-6-7
最后登录
2019-3-31
发表于 2008-6-19 21:02:08 |显示全部楼层
楼主辛苦啦!谢谢分享,o(∩_∩)o...

使用道具 举报

Rank: 1

精华
0
UID
1724
积分
34
帖子
5
主题
1
阅读权限
10
注册时间
2008-6-7
最后登录
2019-3-31
发表于 2008-6-19 21:02:18 |显示全部楼层
楼主辛苦啦!谢谢分享,o(∩_∩)o...

使用道具 举报

您需要登录后才可以回帖 登录 | 注册

bottom

静态版|手机版|联系我们|交易开拓者 ( 粤ICP备07044698   

GMT+8, 2020-12-2 20:05

Powered by Discuz! X2 LicensedChrome插件扩展

© 2011-2012 交易开拓者 Inc.

回顶部