快捷导航

开拓者期货期权程序化系统交易论坛 › 论坛 › 产品与服务 › 开户咨询 › (原创)原版海龟交易系统

返回列表

查看: 13017|回复: 8

(原创)原版海龟交易系统 [复制链接]

米小兔

中级散户

Rank: 3 Rank: 3

精华: 0
UID: 116726
积分: 166
帖子: 57
主题: 8
阅读权限: 40
注册时间: 2013-4-2
最后登录: 2014-7-16

电梯直达

1^#

发表于 2013-6-3 17:10:57 |只看该作者 |倒序浏览

本帖最后由米小兔于 2013-6-3 17:15 编辑

tb自带的海龟交易系统有些问题,还比较严重,和海龟交易系统原版意思差得有点远.试着在tb自带的源码中修改,改来改去未达到效果,索性重写了一个.
在仔细阅读海龟交易系统的中文说明的时候,发现有些问题没有说清楚,例如首次开仓和后面三次加仓的仓位分别是多少.针对这一点,我理解为每次加仓都按照当时最新账户权益计算出标准头寸,也就意味着首次开仓和后面三次加仓的仓位都可能不一样,规律是后面开仓的手数可能会大于前面的,因为满足加仓的时候肯定是有盈利的.
附件的压缩包有两个版本的系统文件,V103在前一个版本基础上增加了手工判定多空趋势的参数,这也是应广大客户需求所加入进去,这样就可以加入人为的趋势判断进去了.Numeric Direction(0);    // 多空信号过滤条件,值为0不过滤,值为1只做多,值为1只做空;
如果有朋友需要源码,可以联系我.
版本:ITF_TurtleRules_V102
 关键变量的计算
1) N值的计算
每天开盘第一根k线计算前LengthAtr长度的平均真实波幅;
2) 价值波动 = N*每点的价值(ContractUnit()*BigPointValue())
3) 标准头寸计算
根据每天开盘时计算的N和价值波动率计算最新标准头寸.
标准单位头寸(TurtleUnits) = (k线开盘价计算的动态权益*风险比例)/价值波动率;
 首次入市条件
1) LengthFast(20)长度的唐奇安通道突破;
2) LengthSlow(55)长度的唐奇安通道突破;
备注:前一次平仓是因为止损,随后的开仓需满足条件一入市.如果前一次平仓是一般离市,则随后的开仓需满足条件二入市;
 加仓
1) 与最近一次开仓价格间隔1/2倍N增加仓位;
 止损
1) 最近一次开仓价格反向2N;
 离市
1) LengthExit(10)长度的唐奇安通道被方向突破;
      2) LengthAtr(20)长度的唐奇安通道被方向突破;
 参数说明
Numeric RiskRatio(1);             // % Risk Per N ( 0 - 100)
Numeric LengthAtr(20);             // 平均波动周期 ATR Length
Numeric LengthFast(20);          // 短周期 BreakOut Length
Numeric LengthSlow(55);          // 长周期 FailSafe Length
Numeric LengthExit(10);          // 离市周期 Trailing Exit Length
Bool LastProfitableTradeFilter(True); // 使用入市过滤条件

 适用环境
      软体:TB V4.3.6
      K线图表:15分\30分
      品种:所有
 测试
      品种选择:RU\TA\RB\J
      本金:200万,每个品种按照100万初始资金计算仓位;
      时间:2009年1月1日-2013年6月3日
      净值曲线图:

      最大回撤比例:23.66% 回撤值:47.36万发生时间:2011年9月22日
      最大回撤值:47.36万回撤比例:23.66% 发生时间:2011年9月22日
      累计净利润:597万
      净值:3.99
版本:ITF_TurtleRules_V103
 改进
      1) 增加多空趋势判别参数Direction, 值为0不过滤,值为1只做多,值为1只做空;

 参数
Numeric Direction(0);                // 多空信号过滤条件,值为0不过滤,值为1只做多,值为1只做空;
      Numeric RiskRatio(1);                // % Risk Per N ( 0 - 100)
      Numeric LengthAtr(20);                // 平均波动周期 ATR Length
      Numeric LengthFast(20);                // 短周期 BreakOut Length
      Numeric LengthSlow(55);                // 长周期 FailSafe Length
      Numeric LengthExit(10);                // 离市周期 Trailing Exit Length
      Bool LastProfitableTradeFilter(True); // 使用入市过滤条件

 适用环境
      软体:TB V4.3.6
      K线图表:15分钟图
      品种:所有

 联系我们
      国贸期货上海营业部量化组
      电话:021-51969281
      邮箱:yuwy@itf.com.cn
      地址:上海张杨路620号东楼902室
      客服热线:4008888958
      网址:www.itf.com.cn

附件: 你需要登录才可以下载或查看附件。没有帐号？注册

收藏6

使用道具举报

天崖

初级大户

Rank: 5 Rank: 5

精华: 0
UID: 73474
积分: 1249
帖子: 695
主题: 30
阅读权限: 60
注册时间: 2011-10-22
最后登录: 2015-11-6

2^#

发表于 2013-6-4 17:18:30 |只看该作者

我已经领取模型源码，绩效稳健，顶~~~~~~~~~~~~~~~

使用道具举报

myamin

期市新手

Rank: 1

精华: 0
UID: 117571
积分: 20
帖子: 7
主题: 0
阅读权限: 10
注册时间: 2013-4-13
最后登录: 2013-9-8

3^#

发表于 2013-6-15 15:40:22 |只看该作者

已经领取模型源码，绩效稳健，顶

使用道具举报

米小兔

中级散户

Rank: 3 Rank: 3

精华: 0
UID: 116726
积分: 166
帖子: 57
主题: 8
阅读权限: 40
注册时间: 2013-4-2
最后登录: 2014-7-16

4^#

发表于 2013-6-18 14:31:19 |只看该作者

有不少要源码的朋友,我就不一一发了,把源码贴上供大家交流指正.

//------------------------------------------------------------------------
// 简称: ITF_TurtleRules_V102
// 名称: TurtleRules_V102
// 类别: 公式应用
// 类型: 用户应用
// 输出:
//------------------------------------------------------------------------
Params
Numeric RiskRatio(1); // % Risk Per N ( 0 - 100)
Numeric LengthAtr(20); // 平均波动周期 ATR Length
Numeric LengthFast(20); // 短周期 BreakOut Length
Numeric LengthSlow(55); // 长周期 FailSafe Length
Numeric LengthExit(10); // 离市周期 Trailing Exit Length
Bool LastProfitableTradeFilter(True); // 使用入市过滤条件
Vars
Numeric MinPoint; // 最小变动单位
NumericSeries N; // N 值
NumericSeries TotalEquity; // 按最新收盘价计算出的总资产
NumericSeries TurtleUnits; // 交易单位
NumericSeries DonchianFastUpper; // 短周期唐奇安通道上轨,长度LengthFast;
NumericSeries DonchianFastLower; // 短周期唐奇安通道下轨,长度LengthFast;
NumericSeries DonchianSlowUpper; // 长周期唐奇安通道上轨,长度LengthSlow;
NumericSeries DonchianSlowLower; // 长周期唐奇安通道下轨,长度LengthSlow;
NumericSeries DonchianExitUpper; // 离市时判断需要的N周期最高价,长度LengthExit;
NumericSeries DonchianExitLower; // 离市时判断需要的N周期最低价,长度LengthExit;
NumericSeries MyPrice; // 开仓价格
NumericSeries MyExitPrice; // 平仓价格
BoolSeries PreBreakoutFailure(false); // 前一次突破是否失败
Bool SendOrderThisBar(False); // 当前Bar有过交易
NumericSeries AtrAve; // 记录日线级别长度为lengthAtr的平均真实波幅;
NumericSeries DayHigh; // 一天中的最高价;
NumericSeries DayLow; // 一天中的最低价;
Numeric i; // 循环计算所需指针;
NumericSeries Atr(0); // 当天的ATR
Numeric AtrIndex(0); // 存储真实波幅的全局变量的环的索引值;
NumericSeries DayCount(0); // 交易日数;
NumericSeries CloseD_1; // 上一个交易日收盘价,过度CloseD(1);
NumericSeries MyBarsSinceToday; // 过度BarsSinceToday;
Begin
MinPoint = MinMove*PriceScale;
MyBarsSinceToday = BarsSinceToday;
CloseD_1 = CloseD(1);
if(BarsSinceToday==0)
{
DayCount = DayCount + 1; //记录交易日数;
DayHigh = High;
DayLow = Low;
//从第二个交易日开始记录;
if(DayCount>=2)
{
// 前一日真实波幅;
Atr = max(max(Abs(DayHigh[1]-CloseD_1),Abs(DayLow[1]-CloseD_1)),DayHigh[1]-DayLow[1]);
// 存储前一天的Atr到全局变量环0-19;
AtrIndex = (DayCount-2)%LengthAtr;
SetGlobalVar(AtrIndex,Atr[1]);
}
// 从第LengthAtr+1个交易日开始计算;
if(DayCount>=LengthAtr+1)
{
// 计算日线级别长度为LengthAtr的平均真实波幅;
AtrAve = 0 ;
for i=0 to LengthAtr-1
{
AtrAve = AtrAve + getGlobalVar(i);
}
AtrAve = AtrAve/LengthAtr;
N = IntPart(AtrAve);
DonchianFastUpper = Highest(DayHigh[1],(LengthAtr-0.1)*(MyBarsSinceToday[1]+1));
DonchianFastLower = Lowest(DayLow[1],(LengthAtr-0.1)*(MyBarsSinceToday[1]+1));
DonchianSlowUpper = Highest(DayHigh[1],(LengthSlow-0.1)*(MyBarsSinceToday[1]+1));
DonchianSlowLower = Lowest(DayLow[1],(LengthSlow-0.1)*(MyBarsSinceToday[1]+1));
DonchianExitUpper = Highest(DayHigh[1],(LengthExit-0.1)*(MyBarsSinceToday[1]));
DonchianExitLower = Lowest(DayLow[1],(LengthExit-0.1)*(MyBarsSinceToday[1]));
}
//账户最新资产 = 按当前Bar开盘价计算的可用资金 + 持仓保证金 ;
TotalEquity = Portfolio_CurrentCapital() + Portfolio_UsedMargin();
//标准单位头寸 = (本金*风险比例)/价值波动率
TurtleUnits = (TotalEquity*RiskRatio/100) /(N * ContractUnit()*BigPointValue());
TurtleUnits = IntPart(TurtleUnits); // 对小数取整
// PlotString("Units","Units="+Text(TurtleUnits),High+(High-Low),white);
// PlotString("N","N="+Text(N),Low-(High-Low)/2,white);
}
Else
{
DayHigh = Max(DayHigh,High);
DayLow = Min(DayLow,Low);
}
If(MarketPosition==0 and TurtleUnits>=1)
{
// 首次入市1:带过滤条件的,如果过滤条件为真,则需要前一笔交易是否是突破失败;
if(LastProfitableTradeFilter==false Or PreBreakoutFailure )
{
//开多1:突破短周期唐奇安通道上轨;
If(High>DonchianFastUpper)
{
MyPrice = Max(Open,DonchianFastUpper)+MinPoint;
Buy(TurtleUnits,MyPrice);
MyExitPrice = MyPrice - 2*N;
SendOrderThisBar = true;
}
//开空1:突破短周期唐奇安通道下轨;
if(Low<DonchianFastLower)
{
MyPrice = Min(Open,DonchianFastLower)-MinPoint;
SellShort(TurtleUnits,MyPrice);
MyExitPrice = MyPrice + 2*N;
SendOrderThisBar = true;
}
}
// 首次入市2:过滤条件之外的,长周期唐奇安通道突破开仓;
//开多2:突破长周期唐奇安通道上轨;
else
{
if(CrossOver(High,DonchianSlowUpper))
{
MyPrice = Max(Open,DonchianSlowUpper)+MinPoint;
Buy(TurtleUnits,MyPrice);
MyExitPrice = MyPrice - 2*N;
SendOrderThisBar = true;
}
//开空2:突破长周期唐奇安通道下轨;
if(CrossUnder(Low,DonchianSlowLower))
{
MyPrice = Min(Open,DonchianSlowLower)+MinPoint;
SellShort(TurtleUnits,MyPrice);
MyExitPrice = MyPrice + 2*N;
SendOrderThisBar = true;
}
}
}
// 当持有多单;
if(MarketPosition==1)
{
//离市:价格反向穿越离市的唐奇安通道;
if(CrossUnder(Low,DonchianExitLower))
{
MyPrice = Min(Open,DonchianExitLower)-MinPoint;
Sell(0,MyPrice);
PreBreakoutFailure = False; //假突破值为假;
// PlotBool("突破",PreBreakoutFailure,High,white);
}
Else
{
//加仓:与最近一次开仓价间隔0.5*N开仓;
if(High>LastEntryPrice+0.5*N and TurtleUnits>=1)
{
MyPrice = Max(Open,LastEntryPrice+0.5*N)-MinPoint;
Buy(TurtleUnits,MyPrice);
SendOrderThisBar = true;
}
//止损:价格反向穿越最近一次开仓价格-2N;
if(Low<LastEntryPrice-2*N)
{
MyPrice = Min(Open,LastEntryPrice-2*N)-MinPoint;
Sell(0,MyPrice);
PreBreakoutFailure = True; //假突破值为真;
// PlotBool("突破",PreBreakoutFailure,High,white);
}
}
}
// 当持有空单;
else if(MarketPosition==-1)
{
// 离市:价格反向穿越离市的唐奇安通道;
if(CrossOver(High,DonchianExitUpper))
{
MyPrice = Max(Open,DonchianExitUpper)+MinPoint;
BuyToCover(0,MyPrice);
PreBreakoutFailure = False; //假突破值为假;
// PlotBool("突破",PreBreakoutFailure,High,white);
}
Else
{
// 加仓:与最近一次开仓价格间隔0.5*N开仓;
if(Low<LastEntryPrice-0.5*N and TurtleUnits>=1)
{
MyPrice = Min(Open,LastEntryPrice-0.5*N)-MinPoint;
SellShort(TurtleUnits,MyPrice);
SendOrderThisBar = true;
}
// 止损:价格反向穿越最近一次开仓价格+2N;
if(High>LastEntryPrice+2*N)
{
MyPrice = Max(Open,LastEntryPrice+2*N)+MinPoint;
BuyToCover(0,MyPrice);
PreBreakoutFailure = True; //假突破值为真;
// PlotBool("突破",PreBreakoutFailure,High,white);
}
}
}
PlotNumeric("DonchianFastUpper",DonchianFastUpper);
PlotNumeric("DonchianFastLower",DonchianFastLower);
PlotNumeric("DonchianSlowUpper",DonchianSlowUpper);
PlotNumeric("DonchianSlowLower",DonchianSlowLower);
PlotNumeric("DonchianExitUpper",DonchianExitUpper);
PlotNumeric("DonchianExitLower",DonchianExitLower);
// Commentary("点值="+Text(ContractUnit()*BigPointValue()));
Commentary("TotalEquity="+Text(TotalEquity));
Commentary("N="+Text(N));
Commentary("Units="+Text(TurtleUnits));
// Commentary("Atr="+Text(Atr));
// Commentary("AtrAve="+Text(AtrAve));
// PlotNumeric("AtrAve",AtrAve);
Commentary("DayCount="+Text(DayCount));
Commentary("MyBarsSinceToday="+Text(MyBarsSinceToday[1]+1));
if(PreBreakoutFailure == True)
{
Commentary("PreBreakoutFailure = True");
}Else
{
Commentary("PreBreakoutFailure = false");
}
if(LastProfitableTradeFilter==true)
{
Commentary("LastProfitableTradeFilter = True");
}Else
{
Commentary("LastProfitableTradeFilter = False");
}
End
//------------------------------------------------------------------------
// 编译版本 GS2010.12.08
// 用户版本 2013/05/08 22:28
// 版权所有 arowana
// 更改声明 TradeBlazer Software保留对TradeBlazer平台
// 每一版本的TrabeBlazer公式修改和重写的权利
//------------------------------------------------------------------------

复制代码

使用道具举报

guoguosh

期市新手

Rank: 1

精华: 0
UID: 117100
积分: 12
帖子: 2
主题: 0
阅读权限: 10
注册时间: 2013-3-28
最后登录: 2013-6-27

5^#

发表于 2013-6-27 14:50:21 |只看该作者

不错

使用道具举报

米小兔

中级散户

Rank: 3 Rank: 3

精华: 0
UID: 116726
积分: 166
帖子: 57
主题: 8
阅读权限: 40
注册时间: 2013-4-2
最后登录: 2014-7-16

6^#

发表于 2013-6-28 11:04:15 |只看该作者

修改:加仓判断条件改为以最高价或最低价循环判断满足加仓条件,实现一根k线满足多次加仓条件;

Params
Numeric Direction(0); // 多空信号过滤条件,值为0不过滤,值为1只做多,值为1只做空;
Numeric RiskRatio(1); // % Risk Per N ( 0 - 100)
Numeric LengthAtr(20); // 平均波动周期 ATR Length
Numeric LengthFast(20); // 短周期 BreakOut Length
Numeric LengthSlow(55); // 长周期 FailSafe Length
Numeric LengthExit(10); // 离市周期 Trailing Exit Length
Bool LastProfitableTradeFilter(True); // 使用入市过滤条件
Vars
Numeric MinPoint; // 最小变动单位
NumericSeries N; // N 值
NumericSeries TotalEquity; // 按最新收盘价计算出的总资产
NumericSeries TurtleUnits; // 交易单位
NumericSeries DonchianFastUpper; // 短周期唐奇安通道上轨,长度LengthFast;
NumericSeries DonchianFastLower; // 短周期唐奇安通道下轨,长度LengthFast;
NumericSeries DonchianSlowUpper; // 长周期唐奇安通道上轨,长度LengthSlow;
NumericSeries DonchianSlowLower; // 长周期唐奇安通道下轨,长度LengthSlow;
NumericSeries DonchianExitUpper; // 离市时判断需要的N周期最高价,长度LengthExit;
NumericSeries DonchianExitLower; // 离市时判断需要的N周期最低价,长度LengthExit;
NumericSeries MyPrice;
NumericSeries MyExitPrice; // 平仓价格
NumericSeries preEntryPrice(0); // 前一次开仓的价格
BoolSeries PreBreakoutFailure(false); // 前一次突破是否失败
Bool SendOrderThisBar(False); // 当前Bar有过交易
NumericSeries AtrAve; // 记录日线级别长度为lengthAtr的平均真实波幅;
NumericSeries DayHigh; // 一天中的最高价;
NumericSeries DayLow; // 一天中的最低价;
Numeric i; // 循环计算所需指针;
NumericSeries Atr(0); // 当天的ATR
Numeric AtrIndex(0); // 存储真实波幅的全局变量的环的索引值;
NumericSeries DayCount(0); // 交易日数;
NumericSeries CloseD_1; // 上一个交易日收盘价,过度CloseD(1);
NumericSeries MyBarsSinceToday; // 过度BarsSinceToday;
Begin
MinPoint = MinMove*PriceScale;
MyBarsSinceToday = BarsSinceToday;
CloseD_1 = CloseD(1);
if(BarsSinceToday==0)
{
DayCount = DayCount + 1; //记录交易日数;
DayHigh = High;
DayLow = Low;
//从第二个交易日开始记录;
if(DayCount>=2)
{
// 前一日真实波幅;
Atr = max(max(Abs(DayHigh[1]-CloseD_1),Abs(DayLow[1]-CloseD_1)),DayHigh[1]-DayLow[1]);
// 存储前一天的Atr到全局变量环0-19;
AtrIndex = (DayCount-2)%LengthAtr;
SetGlobalVar(AtrIndex,Atr[1]);
}
// 从第LengthAtr+1个交易日开始计算;
if(DayCount>=LengthAtr+1)
{
// 计算日线级别长度为LengthAtr的平均真实波幅;
AtrAve = 0 ;
for i=0 to LengthAtr-1
{
AtrAve = AtrAve + getGlobalVar(i);
}
AtrAve = AtrAve/LengthAtr;
N = IntPart(AtrAve);
DonchianFastUpper = Highest(DayHigh[1],(LengthAtr-0.1)*(MyBarsSinceToday[1]+1));
DonchianFastLower = Lowest(DayLow[1],(LengthAtr-0.1)*(MyBarsSinceToday[1]+1));
DonchianSlowUpper = Highest(DayHigh[1],(LengthSlow-0.1)*(MyBarsSinceToday[1]+1));
DonchianSlowLower = Lowest(DayLow[1],(LengthSlow-0.1)*(MyBarsSinceToday[1]+1));
DonchianExitUpper = Highest(DayHigh[1],(LengthExit-0.1)*(MyBarsSinceToday[1]));
DonchianExitLower = Lowest(DayLow[1],(LengthExit-0.1)*(MyBarsSinceToday[1]));
}
//账户最新资产 = 按当前Bar开盘价计算的可用资金 + 持仓保证金 ;
TotalEquity = Portfolio_CurrentCapital() + Portfolio_UsedMargin();
//标准单位头寸 = (本金*风险比例)/价值波动率
TurtleUnits = (TotalEquity*RiskRatio/100) /(N * ContractUnit()*BigPointValue());
TurtleUnits = IntPart(TurtleUnits); // 对小数取整
// PlotString("Units","Units="+Text(TurtleUnits),High+(High-Low),white);
// PlotString("N","N="+Text(N),Low-(High-Low)/2,white);
}
Else
{
DayHigh = Max(DayHigh,High);
DayLow = Min(DayLow,Low);
}
If(MarketPosition==0 and TurtleUnits>=1)
{
// 首次入市1:带过滤条件的,如果过滤条件为真,则需要前一笔交易是否是突破失败;
if(LastProfitableTradeFilter==false Or PreBreakoutFailure )
{
//开多1:突破短周期唐奇安通道上轨;
If(High>DonchianFastUpper and Direction!=-1)
{
MyPrice = Max(Open,DonchianFastUpper)+MinPoint;
preEntryPrice = MyPrice;
Buy(TurtleUnits,MyPrice);
MyExitPrice = MyPrice - 2*N;
SendOrderThisBar = true;
}
//开空1:突破短周期唐奇安通道下轨;
if(Low<DonchianFastLower and Direction!=1)
{
MyPrice = Min(Open,DonchianFastLower)-MinPoint;
preEntryPrice = MyPrice;
SellShort(TurtleUnits,MyPrice);
MyExitPrice = MyPrice + 2*N;
SendOrderThisBar = true;
}
}
// 首次入市2:过滤条件之外的,长周期唐奇安通道突破开仓;
//开多2:突破长周期唐奇安通道上轨;
else
{
if(CrossOver(High,DonchianSlowUpper) and Direction!=-1)
{
MyPrice = Max(Open,DonchianSlowUpper)+MinPoint;
preEntryPrice = MyPrice;
Buy(TurtleUnits,MyPrice);
MyExitPrice = MyPrice - 2*N;
SendOrderThisBar = true;
}
//开空2:突破长周期唐奇安通道下轨;
if(CrossUnder(Low,DonchianSlowLower) and Direction!=1)
{
MyPrice = Min(Open,DonchianSlowLower)+MinPoint;
preEntryPrice = MyPrice;
SellShort(TurtleUnits,MyPrice);
MyExitPrice = MyPrice + 2*N;
SendOrderThisBar = true;
}
}
}
// 当持有多单;
if(MarketPosition==1)
{
//离市:价格反向穿越离市的唐奇安通道;
if(CrossUnder(Low,DonchianExitLower))
{
MyPrice = Min(Open,DonchianExitLower)-MinPoint;
Sell(0,MyPrice);
PreBreakoutFailure = False; //假突破值为假;
// PlotBool("突破",PreBreakoutFailure,High,white);
}
Else
{
//加仓:如果开盘价就大于最近一次开仓价+0.5*N,则以开盘价发单;
if(Open>LastEntryPrice+0.5*N and TurtleUnits>=1)
{
MyPrice = Open;
preEntryPrice = MyPrice;
Buy(TurtleUnits,MyPrice);
SendOrderThisBar = true;
}
// 以最高价为标准，判断能进行几次增仓
while(High >= preEntryPrice + 0.5*N)
{
MyPrice = preEntryPrice + 0.5 * N;
preEntryPrice = MyPrice;
Buy(TurtleUnits,MyPrice);
SendOrderThisBar = True;
}
//止损:价格反向穿越最近一次开仓价格-2N;
if(Low<LastEntryPrice-2*N)
{
MyPrice = Min(Open,LastEntryPrice-2*N)-MinPoint;
Sell(0,MyPrice);
PreBreakoutFailure = True; //假突破值为真;
// PlotBool("突破",PreBreakoutFailure,High,white);
}
}
}
// 当持有空单;
else if(MarketPosition==-1)
{
// 离市:价格反向穿越离市的唐奇安通道;
if(CrossOver(High,DonchianExitUpper))
{
MyPrice = Max(Open,DonchianExitUpper)+MinPoint;
BuyToCover(0,MyPrice);
PreBreakoutFailure = False; //假突破值为假;
// PlotBool("突破",PreBreakoutFailure,High,white);
}
Else
{
// 加仓:与最近一次开仓价格间隔0.5*N开仓;
if(Open<LastEntryPrice-0.5*N and TurtleUnits>=1)
{
MyPrice = Open;
preEntryPrice = MyPrice;
SellShort(TurtleUnits,MyPrice);
SendOrderThisBar = true;
}
// 以最低价为标准，判断能进行几次增仓
while(Low <= preEntryPrice - 0.5*N)
{
MyPrice = preEntryPrice - 0.5 * N;
preEntryPrice = MyPrice;
SellShort(TurtleUnits,MyPrice);
SendOrderThisBar = True;
}
// 止损:价格反向穿越最近一次开仓价格+2N;
if(High>LastEntryPrice+2*N)
{
MyPrice = Max(Open,LastEntryPrice+2*N)+MinPoint;
BuyToCover(0,MyPrice);
PreBreakoutFailure = True; //假突破值为真;
// PlotBool("突破",PreBreakoutFailure,High,white);
}
}
}
PlotNumeric("DonchianFastUpper",DonchianFastUpper);
PlotNumeric("DonchianFastLower",DonchianFastLower);
PlotNumeric("DonchianSlowUpper",DonchianSlowUpper);
PlotNumeric("DonchianSlowLower",DonchianSlowLower);
PlotNumeric("DonchianExitUpper",DonchianExitUpper);
PlotNumeric("DonchianExitLower",DonchianExitLower);
// Commentary("点值="+Text(ContractUnit()*BigPointValue()));
Commentary("TotalEquity="+Text(TotalEquity));
Commentary("N="+Text(N));
Commentary("Units="+Text(TurtleUnits));
// Commentary("Atr="+Text(Atr));
// Commentary("AtrAve="+Text(AtrAve));
// PlotNumeric("AtrAve",AtrAve);
Commentary("DayCount="+Text(DayCount));
Commentary("MyBarsSinceToday="+Text(MyBarsSinceToday[1]+1));
End

复制代码

使用道具举报

bbenben

中级散户

Rank: 3 Rank: 3

精华: 0
UID: 5718
积分: 141
帖子: 38
主题: 4
阅读权限: 40
注册时间: 2009-10-21
最后登录: 2013-10-10

7^#

发表于 2013-9-27 11:30:23 |只看该作者

改的不错，max min简化了程序，
还是有一个错误133 MyPrice = Min(Open,DonchianSlowLower)+MinPoint;

使用道具举报

bbenben

中级散户

Rank: 3 Rank: 3

精华: 0
UID: 5718
积分: 141
帖子: 38
主题: 4
阅读权限: 40
注册时间: 2009-10-21
最后登录: 2013-10-10

8^#

发表于 2013-9-27 11:54:44 |只看该作者

98 If(High>DonchianFastUpper and Direction!=-1) //小周期开多仓条件
108  if(Low<DonchianFastLower and Direction!=1)  //小周期开空仓条件
122  if(CrossOver(High,DonchianSlowUpper) and Direction!=-1) //大周期开多仓条件
131 if(CrossUnder(Low,DonchianSlowLower) and Direction!=1) //大周期开空仓条件
146  if(CrossUnder(Low,DonchianExitLower)) //多头离市条件
156 if(Open>LastEntryPrice+0.5*N and TurtleUnits>=1) //多头加仓条件
164 while(High >= preEntryPrice + 0.5*N) //多头加仓条件
172 if(Low<LastEntryPrice-2*N) //多头止损条件
在这里面小周期开仓条件用的是比较式，大周期开仓用的是穿越，多头离市采用的是穿越，设计时是如何考虑的。
加仓和止损采用的都是比较式。
同官方程序相比，大周期开仓和离市改为穿越，主要考虑点是什么？
好像在躲避极端情况下的交易风险，但好像还有漏洞。

使用道具举报