关于返回函数问题

sswywangyun

Begin
        // 说明：此函数可以处理1分钟、3分钟、5分钟、15分钟、30分钟、1小时、日线、周线、月线交易的集合竞价与小节过滤，避免发出废单。
        // 如果使用7分钟、13分钟等特殊时间周期进行交易，请仿照下面的代码自行修改。
       
        // 写成“Date >= CurrentDate”，是为了处理日线交易有夜盘的品种在夜间开盘的集合竞价
        If(BarStatus == 2 And Date >= CurrentDate)
        {
                If(ExchangeName == "上海证券交易所" Or ExchangeName == "深圳证券交易所")
                {
                        // 日线，周线，月线                               
                        If((BarType == 0 Or BarType == 4 Or BarType == 5) And CurrentTime > 0.092455 And CurrentTime < 0.093005) Return False;
                       
                        If(Time == 0.0900 And CurrentTime > 0.092455 And CurrentTime < 0.093005) Return False;
                        If(Time == 0.0930 And CurrentTime < 0.093005) Return False;
                        If(Time == 0.1300 And CurrentTime < 0.130005) Return False;
                }Else If(ExchangeName == "中国金融期货交易所")
                {
                        If (SymbolType == "TF" || SymbolType == "T") // 国债
                        {
                                // 日线，周线，月线                               
                                If((BarType == 0 Or BarType == 4 Or BarType == 5) And CurrentTime > 0.091355 And CurrentTime < 0.091505) Return False;

                                If(Time == 0.0900 And CurrentTime > 0.091355 And CurrentTime < 0.091505) Return False;
                                If(Time == 0.0915 And CurrentTime < 0.091505) Return False;                                       
                        }Else // 股指
                        {
                                // 日线，周线，月线                               
                                If((BarType == 0 Or BarType == 4 Or BarType == 5) And CurrentTime > 0.092855 And CurrentTime < 0.093005) Return False;

                                If(Time == 0.0900 And CurrentTime > 0.092855 And CurrentTime < 0.093005) Return False;
                                If(Time == 0.0930 And CurrentTime < 0.093005) Return False;
                        }
                       
                        If(Time == 0.1300 And CurrentTime < 0.130005) Return False;
                }Else If(ExchangeName == "上海期货交易所" Or ExchangeName == "郑州商品交易所" Or ExchangeName == "大连商品交易所")
                {
                        // 注意：有夜盘的品种的日线工作区在最后一根日线上有信号，并且在0.085855之前打开，则会报信号消失，0.090005之后信号恢复
                        // 有夜盘的品种的日线工作区在最后一根日线上有信号，并且在0.085855到0.090005之间打开，则会在0.090005之后发单
                        // 所以，建议尽量早些打开工作区
                       
                        // 日线，周线，月线
                        If((BarType == 0 Or BarType == 4 Or BarType == 5) And CurrentTime > 0.205855 And CurrentTime < 0.210005) Return False;
                        If((BarType == 0 Or BarType == 4 Or BarType == 5) And CurrentTime > 0.085855 And CurrentTime < 0.090005) Return False;
                               
                        If(Time == 0.2100 And CurrentTime < 0.210005) Return False;
                        If(Time == 0.0900 And CurrentTime < 0.090005) Return False;
                        If(Time == 0.1030 And CurrentTime < 0.103005) Return False;
                       
                        // 注意商品1小时K线下午开始时间是0.1300
                        If((Time == 0.1300 Or Time == 0.1330) And CurrentTime < 0.133005) Return False;
                }
        }
       
        Return True;
End



老师为什么上面都是Return False;   最后又是Return True;            然后引用用户函数的时候又是不等于这个条件if(!CallAuctionFilter)  Return  我很难理解

小米

这个函数的代码，你可以理解为上述各条件满足后的return false就都为假了，
除了上述条件外的其它情况下就是为真的。。
而在公式应用代码中使用的意思是，当这个函数不为真时，后面的语句就不执行了。。

sswywangyun

小米 发表于 2016-8-3 11:21
这个函数的代码，你可以理解为上述各条件满足后的return false就都为假了，
除了上述条件外的其它情况下就 ...

谢谢猫哥