免费文化TB转模型互转，只要你有好的文化或者TB模型，我都可以免费帮你互转。 [复制链接]

zxjt30920087

期市新手

Rank: 1

精华: 0
UID: 253578
积分: 48
帖子: 31
主题: 5
阅读权限: 10
注册时间: 2017-7-7
最后登录: 2018-5-17

电梯直达

1^#

发表于 2017-7-22 09:30:18 |只看该作者 |倒序浏览

免费文化TB转模型互转，只要你有好的文化或者TB模型，我都可以免费帮你互转。

会编程就是没有好的思路，只要您有好的思路也可以免费编程，实现共赢，qq523305738

下面分享一个tb的模型，还请高手们多指教。

//------------------------------------------------------------------------
// 简称: BT
// 名称: 本体
// 类别: 公式应用
// 类型: 用户应用
// 输出: Void
//------------------------------------------------------------------------
Params
Numeric SS(1);//(1,100,1)
Numeric K1(0.3);//(0.1,1,0.1)
Numeric K2(0.6);//(0.1,1,0.1)
Numeric BOCP(0.25);//(0,1,0.01)
Numeric FBOCP(0.85);//(0,1,0.01)
Numeric AR(6);
Vars
Numeric Longtrade(0);//多仓次数
Numeric Shorttrade(0);//空仓次数
Numeric LMarket(0);//趋买市
Numeric SMarket(0);//趋卖市
Numeric LStop(0);//多头止损价
Numeric SStop(0);//空头止损价
Numeric i;
Numeric AR10(0);//十日平均波幅
Numeric ACO10(0);//十日平均开收盘区间
Bool key(False);//进场条件
Numeric LBreak;//多头突破价
Numeric SBreak;//空头突破价
Numeric LToS;//多翻空
Numeric SToL;//空翻多
Numeric Lots;//开仓量
Numeric LBuy;//趋买市多头入场价
Numeric LSell;//趋买市空头入场价
Numeric SBuy;//趋卖市多头入场价
Numeric SSell;//趋卖市空头入场价
NumericSeries O1;
NumericSeries C1;
NumericSeries C2;
NumericSeries L1;
NumericSeries H1;
NumericSeries H0;
NumericSeries L0;
NumericSeries O0;
Numeric LL3;
Numeric HH3;
//AR计算
NumericSeries AR_1(0);
NumericSeries AR_2(0);
Begin
//本策略适用于股指5分钟线，如要使用其他周期及商品，请自行修改时间
O1 = OpenD(1);
C1 = CloseD(1);
C2 = CloseD(2);
L1 = LowD(1);
H1 = HighD(1);
H0 = Highest(High[1],BarsSinceToday-1);
L0 = Lowest(Low[1],BarsSinceToday-1);
O0 = OpenD(0);
LL3 = Lowest(Low[1],3);
HH3 = Highest(High[1],3);
ACO10=0;
AR10=0;
AR10=AR_D(10);
Commentary("AR10="+Text(AR10 ));
ACO10 = ACO(10);
Commentary("ACO10="+Text(ACO10 ));
key = Abs(C1 - O1) < 0.85*ACO10;//0.85
LBreak = H1 + BOCP * AR10;
SBreak = L1 - BOCP * AR10;
LToS = L1 + FBOCP * AR10;
SToL = H1 - FBOCP * AR10;
//PlotNumeric("LBreak",LBreak);
//PlotNumeric("SBreak",SBreak);
//PlotNumeric("LToS",LToS);
//PlotNumeric("SToL",SToL);
Lots = SS;
//LBuy = O0 + K1 * AR10;
//LSell = O0 - K2 * AR10;
//PlotNumeric("LBuy",LBuy);
//PlotNumeric("LSell",LSell);
//开仓条件
If(C1<C2) //趋买市
{
LMarket = 1;
LBuy = O0 + K1 * AR10;
LSell = O0 - K2 * AR10;
PlotNumeric("LBuy",LBuy);
PlotNumeric("LSell",LSell);
}
If(C1>C2)//趋卖市
{
SMarket = 1;
SBuy = O0 + K2 * AR10;
SSell = O0 - K1 * AR10;
PlotNumeric("SBuy",SBuy);
PlotNumeric("SSell",SSell);
}
//----------------------交易系统-----------------------------
//-----------突破-----------
If(Time>9.45/100 And Time<14.30/100 And key)
{
//趋买市
If(LMarket==1)
{
If(Longtrade==0 && C[1] > LBuy && MarketPosition==0 && BarsSinceEntry>0)//BarsSinceEntry>0
{
Buy(Lots,O);
LStop = Min(EntryPrice-0.25*AR10,EntryPrice-3*BigPointValue);
Longtrade=1;
Return;
}
If(Shorttrade==0 && C[1] < LSell && MarketPosition==0 && BarsSinceEntry>0)//&& BarsSinceEntry>0
{
SellShort(Lots,O);
SStop = Max(EntryPrice+0.25*AR10,EntryPrice+3*BigPointValue);
Shorttrade=1;
Return;
}
}
//趋卖市
If(SMarket==1)
{
If(Longtrade==0 && C[1] > SBuy && MarketPosition==0 && BarsSinceEntry>0)// && BarsSinceEntry>0
{
Buy(Lots,O);
LStop = Min(EntryPrice-0.25*AR10,EntryPrice-3*BigPointValue);
Longtrade=1;
Return;
}
If(Shorttrade==0 && C[1] < SSell && MarketPosition==0 && BarsSinceEntry>0)// && BarsSinceEntry>0
{
SellShort(Lots,O);
SStop = Max(EntryPrice+0.25*AR10,EntryPrice+3*BigPointValue);
Shorttrade=1;
Return;
}
}
}
//-----------突破失败-----------
//{多头突破失败情况1:价格曾经高于多头突破确认价，最新价又回落至空翻多确认价}
If(H0 > LBreak And C[1] < LToS And Time < 14.30/100 And Shorttrade==0 && MarketPosition<>1)
{
SellShort(Lots,O);
SStop=Min(EntryPrice+0.15*AR10,EntryPrice+3*BigPointValue);
Shorttrade=1;
Return;
}
//{多头突破失败情况2:突破入场后,行情反转。止损的同时我们反手开空，但前提是时间在中午11:30之前，
//且多头进场在至少4根K之前。瞬间止损我们不允许反转，因为这往往是市场的膝跳反射}
If(MarketPosition==1 And Time < 14.30/100 And Shorttrade==0)
{
If(C[1] < LStop)
{
Sell(Lots,O);
If(Time < 11.00/100 And BarsSinceEntry >4)
{
SellShort(Lots,C);
SStop=Min(EntryPrice+0.15*AR10,EntryPrice+3*BigPointValue);
Shorttrade=1;
}
}
}
//{空头突破失败情况1:价格曾经低于空头突破确认价，最新价又上涨至空翻多确认价}
If(L0<SBreak And C[1] > SToL And Time < 14.30/100 And Longtrade==0 && MarketPosition<>-1)
{
Buy(Lots,O);
Longtrade=1;
}
//{空头突破失败情况2:突破入场后,行情反转。止损的同时我们反手开多，但前提是时间在中午11:30之前，
//且空头进场在至少4根K之前。瞬间止损我们不允许反转，因为这往往是市场的膝跳反射}
If(MarketPosition==-1 And Time < 14.30/100 And Longtrade==0)
{
If(C[1] > SStop)
{
BuyToCover(Lots,O);
If(Time < 11.00/100 And BarsSinceEntry >4)
{
Buy(Lots,O);
LStop=Max(EntryPrice-0.15*AR10,EntryPrice-3*BigPointValue);
Longtrade=1;
}
}
}
//-----------止损-----------
//普通止损
If(MarketPosition==1 && C[1]<LStop And Time<15.00/100)
{
Sell(Lots,O);
}
If(MarketPosition==-1 && C[1]>SStop And Time<15.00/100)
{
BuyToCover(Lots,O);
}
//止损价调整
//{若持多单，而5分钟K高点超过了开仓价+50%10日平均波幅，止损调整为保本型 }
IF(H0>EntryPrice+0.5*AR10)
{
LStop=EntryPrice+2*BigPointValue;
}
IF(L0<EntryPrice-0.5*AR10)
{
SStop=EntryPrice-2*BigPointValue;
}
//{若时间处于14:30以后，多头跟踪止损为过去3个5分钟的最高低点与多空头止损价中的较大值}
IF(TIME>=14.30/100)
{
LStop=MAX(LStop,LL3);
SStop=MIN(SStop,HH3);
}
//-----------日内平仓-----------
IF(TIME>=14.55/100)
{
//收盘平多
SELL(0,O);
//收盘平空
BuyToCover(0,O);
LMarket=0;
SMarket=0;
Longtrade=0;
Shorttrade=0;
LStop=0;
SStop=0;
}
End
//------------------------------------------------------------------------
// 编译版本: 2017-07-10 082154
// 内核版本: V2.6.2.14
// 版权所有 zxjt30920087
// 更改声明 TradeBlazer Software保留对TradeBlazer平台
// 每一版本的TradeBlazer公式修改和重写的权利
//------------------------------------------------------------------------