请教如何将指数合约出现的交易信号运用到主力合约上面

houyiru198321

请教版主和诸位高手：
1.我设想：橡胶主力合约的进出场能够依据橡胶指数合约在加载了交易模型后出现的交易信号进行。请问如何设置？怎么实现？请您说明具体的操作步骤
2.我利用模拟账户进行了交易，发现其中有一些滑点，请问如何设置能够尽量减少滑点的出现？
3.如果日后进行实仓交易时，滑点与现在用模拟账户进行交易有没有区别？区别在哪里？
谢谢不吝赐教！

lh948

1.在主力合约上叠加指数
参考：
http://www.tradeblazer.net/forum ... &extra=page%3D1
http://www.tradeblazer.net/forum ... &extra=page%3D1
分别为data0和data1
2.交易价格加上偏移的点数
例如：
myEntryPrice = Close +2*PriceScale()*MinMove(); // 在最新价上+2个点。您也可以将Close改为Q_AskPrice(),这样更保险。
3.模拟是过价成交，实盘是撮合成交

houyiru198321

您好，根据您提示的第二个网址中版主的建议，我将橡胶1009主力合约设为主图，然后再插入商品（橡胶指数），然后对原来的海龟进行了修改，加载修改后的海龟。您看修改的对不对，修改后是不是就能实现指数合约出现的信号，在主力合约上面进出场了。
Params
    Numeric RiskRatio(1);                   // % Risk Per N ( 0 - 100)
    Numeric ATRLength(20);                  // 平均波动周期 ATR Length
    Numeric boLength(20);                   // 短周期 BreakOut Length
    Numeric fsLength(55);                   // 长周期 FailSafe Length
    Numeric teLength(10);                   // 离市周期 Trailing Exit Length
    Bool LastProfitableTradeFilter(True);   // 使用入市过滤条件
Vars
        Numeric MinPoint;                       // 最小变动单位
    Numeric N;                              // N 值
    Numeric TotalEquity;                    // 按最新收盘价计算出的总资产
    Numeric TurtleUnits;                    // 交易单位
    NumericSeries DonchianHi;              // 唐奇安通道上轨，延后1个Bar
    NumericSeries DonchianLo;              // 唐奇安通道下轨，延后1个Bar
    NumericSeries fsDonchianHi;            // 唐奇安通道上轨，延后1个Bar，长周期
    NumericSeries fsDonchianLo;            // 唐奇安通道下轨，延后1个Bar，长周期
    Numeric ExitHighestPrice;               // 离市时判断需要的N周期最高价
    Numeric ExitLowestPrice;                // 离市时判断需要的N周期最低价
    Numeric myEntryPrice;                   // 开仓价格
    Numeric myExitPrice;                    // 平仓价格
    Bool SendOrderThisBar(False);          // 当前Bar有过交易
        NumericSeries preEntryPrice(0);       // 前一次开仓的价格，存放到全局变量0号位置
        BoolSeries PreBreakoutFailure(false);        // 前一次突破是否失败
Begin
    If(BarStatus == 0)
    {
                preEntryPrice = InvalidNumeric;
                PreBreakoutFailure = false;
        }Else
        {
                preEntryPrice = preEntryPrice[1];
        PreBreakoutFailure = PreBreakoutFailure[1];
    }

        MinPoint = MinMove*PriceScale;
    N = AverageFC(TrueRange,ATRLength);
    TotalEquity = CurrentCapital()+ Abs(CurrentContracts()*Close*ContractUnit()*BigPointValue()*MarginRatio());
    TurtleUnits = (TotalEquity*RiskRatio/100) /(N * ContractUnit()*BigPointValue());
    TurtleUnits = IntPart(TurtleUnits); // 对小数取整

    DonchianHi = HighestFC(data1.High[1],boLength);
    DonchianLo = LowestFC(data1.Low[1],boLength);

        fsDonchianHi = HighestFC(data1.High[1],fsLength);
    fsDonchianLo = LowestFC(data1.Low[1],fsLength);

        Commentary("N="+Text(N));
        Commentary("preEntryPrice="+Text(preEntryPrice));
        Commentary("PreBreakoutFailure="+IIFString(PreBreakoutFailure,"True","False"));
       
    // 当不使用过滤条件，或者使用过滤条件并且条件为PreBreakoutFailure为True进行后续操作
    If(MarketPosition == 0 && ((!LastProfitableTradeFilter) Or (PreBreakoutFailure)))
    {
        // 突破开仓
        If(CrossOver(data1.High,DonchianHi) && TurtleUnits >= 1)
        {
            // 开仓价格取突破上轨+一个价位和最高价之间的较小值，这样能更接近真实情况，并能尽量保证成交
            myEntryPrice = min(data1.high,DonchianHi + MinPoint);
            myEntryPrice = IIF(myEntryPrice < data1.Open, data1.Open,myEntryPrice); // 大跳空的时候用开盘价代替
                        preEntryPrice = myEntryPrice;
            Buy(TurtleUnits,myEntryPrice);
                        SendOrderThisBar = True;
                        PreBreakoutFailure = False;
        }

        If(CrossUnder(data1.Low,DonchianLo) && TurtleUnits >= 1)
        {
            // 开仓价格取突破下轨-一个价位和最低价之间的较大值，这样能更接近真实情况，并能尽量保证成交
            myEntryPrice = max(data1.low,DonchianLo - MinPoint);
            myEntryPrice = IIF(myEntryPrice > data1.Open, data1.Open,myEntryPrice); // 大跳空的时候用开盘价代替
            preEntryPrice = myEntryPrice;
            SendOrderThisBar = True;
            SellShort(TurtleUnits,myEntryPrice);
                        SendOrderThisBar = True;
                        PreBreakoutFailure = False;
        }
    }

    // 长周期突破开仓 Failsafe Breakout point
    If(MarketPosition == 0)
    {
                Commentary("fsDonchianHi="+Text(fsDonchianHi));
        If(CrossOver(data1.High,fsDonchianHi) && TurtleUnits >= 1)
        {
            // 开仓价格取突破上轨+一个价位和最高价之间的较小值，这样能更接近真实情况，并能尽量保证成交
            myEntryPrice = min(data1.high,fsDonchianHi + MinPoint);
            myEntryPrice = IIF(myEntryPrice < data1.Open, data1.Open,myEntryPrice); // 大跳空的时候用开盘价代替
                        preEntryPrice = myEntryPrice;
            Buy(TurtleUnits,myEntryPrice);
                        SendOrderThisBar = True;
                        PreBreakoutFailure = False;
        }

                Commentary("fsDonchianLo="+Text(fsDonchianLo));
        If(CrossUnder(data1.Low,fsDonchianLo) && TurtleUnits >= 1)
        {
            // 开仓价格取突破下轨-一个价位和最低价之间的较大值，这样能更接近真实情况，并能尽量保证成交
            myEntryPrice = max(data1.low,fsDonchianLo - MinPoint);
            myEntryPrice = IIF(myEntryPrice > data1.Open, data1.Open,myEntryPrice); // 大跳空的时候用开盘价代替
            preEntryPrice = myEntryPrice;
            SellShort(TurtleUnits,myEntryPrice);
                        SendOrderThisBar = True;
                        PreBreakoutFailure = False;
        }
    }

    If(MarketPosition == 1) // 有多仓的情况
    {
        // 求出持多仓时离市的条件比较值
        ExitLowestPrice = Lowest(data1.Low[1],teLength);
                Commentary("ExitLowestPrice="+Text(ExitLowestPrice));
        If(Low < ExitLowestPrice)
        {
            myExitPrice = max(data1.Low,ExitLowestPrice - MinPoint);
                        myExitPrice = IIF(myExitPrice > data1.Open, data1.Open,myExitPrice); // 大跳空的时候用开盘价代替
            Sell(0,myExitPrice);    // 数量用0的情况下将全部平仓
        }Else
        {
            If(preEntryPrice!=InvalidNumeric && TurtleUnits >= 1)
            {
                If(data1.Open >= preEntryPrice + 0.5*N) // 如果开盘就超过设定的1/2N,则直接用开盘价增仓。
                {
                    myEntryPrice = data1.Open;
                                        preEntryPrice = myEntryPrice;
                    Buy(TurtleUnits,myEntryPrice);
                                        SendOrderThisBar = True;
                }

                while(data1.High >= preEntryPrice + 0.5*N) // 以最高价为标准，判断能进行几次增仓
                {
                    myEntryPrice = preEntryPrice + 0.5 * N;
                    preEntryPrice = myEntryPrice;
                    Buy(TurtleUnits,myEntryPrice);
                                        SendOrderThisBar = True;                                       
                }
            }
                       
            // 止损指令
                        If(data1.Low <= preEntryPrice - 2 * N && SendOrderThisBar == false) // 加仓Bar不止损
                        {
                                myExitPrice = preEntryPrice - 2 * N;
                                Sell(0,myExitPrice); // 数量用0的情况下将全部平仓
                                PreBreakoutFailure = True;
                        }
        }
    }Else If(MarketPosition ==-1) // 有空仓的情况
    {
        // 求出持空仓时离市的条件比较值
        ExitHighestPrice = Highest(data1.High[1],teLength);
                Commentary("ExitHighestPrice="+Text(ExitHighestPrice));
        If(data1.High > ExitHighestPrice)
        {
            myExitPrice = Min(data1.High,ExitHighestPrice + MinPoint);
                        myExitPrice = IIF(myExitPrice < data1.Open, data1.Open,myExitPrice); // 大跳空的时候用开盘价代替
            BuyToCover(0,myExitPrice);    // 数量用0的情况下将全部平仓
        }Else
        {
            If(preEntryPrice!=InvalidNumeric && TurtleUnits >= 1)
            {
                If(data1.Open <= preEntryPrice - 0.5*N) // 如果开盘就超过设定的1/2N,则直接用开盘价增仓。
                {
                    myEntryPrice = data1.Open;
                                        preEntryPrice = myEntryPrice;
                    SellShort(TurtleUnits,myEntryPrice);
                                        SendOrderThisBar = True;
                }

                while(data1.Low <= preEntryPrice - 0.5*N) // 以最低价为标准，判断能进行几次增仓
                {
                    myEntryPrice = preEntryPrice - 0.5 * N;
                    preEntryPrice = myEntryPrice;
                    SellShort(TurtleUnits,myEntryPrice);
                                        SendOrderThisBar = True;
                }
            }

            // 止损指令
                        If(data1.High >= preEntryPrice + 2 * N &&SendOrderThisBar==false) // 加仓Bar不止损
                        {
                                myExitPrice = preEntryPrice + 2 * N;
                                BuyToCover(0,myExitPrice); // 数量用0的情况下将全部平仓
                                PreBreakoutFailure = True;
                        }
        }
    }
End

lh948

使用没有问题
用指数的地方，在前面加上data1.
不加data1，默认是data0，则是在原图合约上交易

cnbiz850

3# houyiru198321

我觉得你在设myEntryPrice的时候用了data1（指数）的数据，好像不行吧？

haomai01

也许用这个办法可以解决http://www.tradeblazer.net/forum/thread-18939-1-1.html