TB版海龟的疑问？

z7c9

1. //------------------------------------------------------------------------
   
2. // 简称: TurtleTrader
   
3. // 名称: 海龟交易系统
   
4. // 类别: 交易指令
   
5. // 类型: 其他
   
6. // 输出:
   
7. //------------------------------------------------------------------------
   
8. 
   
9. Params
   
10.     Numeric RiskRatio(1);                   // % Risk Per N ( 0 - 100)
    
11.     Numeric ATRLength(20);                  // 平均波动周期 ATR Length
    
12.     Numeric boLength(20);                   // 短周期 BreakOut Length
    
13.     Numeric fsLength(55);                   // 长周期 FailSafe Length
    
14.     Numeric teLength(10);                   // 离市周期 Trailing Exit Length
    
15.     Bool LastProfitableTradeFilter(True);   // 使用入市过滤条件
    
16. Vars
    
17.         Numeric MinPoint;                       // 最小变动单位
    
18.         NumericSeries AvgTR;                                         // ATR
    
19.     Numeric N;                              // N 值
    
20.     Numeric TotalEquity;                    // 按最新收盘价计算出的总资产
    
21.     Numeric TurtleUnits;                    // 交易单位
    
22.     NumericSeries DonchianHi;              // 唐奇安通道上轨，延后1个Bar
    
23.     NumericSeries DonchianLo;              // 唐奇安通道下轨，延后1个Bar
    
24.     NumericSeries fsDonchianHi;            // 唐奇安通道上轨，延后1个Bar，长周期
    
25.     NumericSeries fsDonchianLo;            // 唐奇安通道下轨，延后1个Bar，长周期
    
26.     Numeric ExitHighestPrice;               // 离市时判断需要的N周期最高价
    
27.     Numeric ExitLowestPrice;                // 离市时判断需要的N周期最低价
    
28.     Numeric myEntryPrice;                   // 开仓价格
    
29.     Numeric myExitPrice;                    // 平仓价格
    
30.     Bool SendOrderThisBar(False);          // 当前Bar有过交易
    
31.         NumericSeries preEntryPrice(0);       // 前一次开仓的价格，存放到全局变量0号位置
    
32.         BoolSeries PreBreakoutFailure(false);        // 前一次突破是否失败
    
33. Begin
    
34.     If(BarStatus == 0)
    
35.     {
    
36.                 preEntryPrice = InvalidNumeric;
    
37.                 PreBreakoutFailure = false;
    
38.         }Else
    
39.         {
    
40.                 preEntryPrice = preEntryPrice[1];
    
41.         PreBreakoutFailure = PreBreakoutFailure[1];
    
42.     }
    
43. 
    
44.         MinPoint = MinMove*PriceScale;
    
45.     AvgTR = XAverage(TrueRange,ATRLength);
    
46.         N = AvgTR[1];
    
47.     TotalEquity = CurrentCapital()+ Abs(CurrentContracts()*Close*ContractUnit()*BigPointValue()*MarginRatio());
    
48.     TurtleUnits = (TotalEquity*RiskRatio/100) /(N * ContractUnit()*BigPointValue());
    
49.     TurtleUnits = IntPart(TurtleUnits); // 对小数取整
    
50. 
    
51.     DonchianHi = HighestFC(High[1],boLength);
    
52.     DonchianLo = LowestFC(Low[1],boLength);
    
53. 
    
54.         fsDonchianHi = HighestFC(High[1],fsLength);
    
55.     fsDonchianLo = LowestFC(Low[1],fsLength);
    
56. 
    
57.         Commentary("N="+Text(N));
    
58.         Commentary("preEntryPrice="+Text(preEntryPrice));
    
59.         Commentary("PreBreakoutFailure="+IIFString(PreBreakoutFailure,"True","False"));
    
60.        
    
61.     // 当不使用过滤条件，或者使用过滤条件并且条件为PreBreakoutFailure为True进行后续操作
    
62.     If(MarketPosition == 0 && ((!LastProfitableTradeFilter) Or (PreBreakoutFailure)))
    
63.     {
    
64.         // 突破开仓
    
65.         If(CrossOver(High,DonchianHi) && TurtleUnits >= 1)
    
66.         {
    
67.             // 开仓价格取突破上轨+一个价位和最高价之间的较小值，这样能更接近真实情况，并能尽量保证成交
    
68.             myEntryPrice = min(high,DonchianHi + MinPoint);
    
69.             myEntryPrice = IIF(myEntryPrice < Open, Open,myEntryPrice); // 大跳空的时候用开盘价代替
    
70.                         preEntryPrice = myEntryPrice;
    
71.             Buy(TurtleUnits,myEntryPrice);
    
72.                         SendOrderThisBar = True;
    
73.                         PreBreakoutFailure = False;
    
74.         }
    
75. 
    
76.         If(CrossUnder(Low,DonchianLo) && TurtleUnits >= 1)
    
77.         {
    
78.             // 开仓价格取突破下轨-一个价位和最低价之间的较大值，这样能更接近真实情况，并能尽量保证成交
    
79.             myEntryPrice = max(low,DonchianLo - MinPoint);
    
80.             myEntryPrice = IIF(myEntryPrice > Open, Open,myEntryPrice); // 大跳空的时候用开盘价代替
    
81.             preEntryPrice = myEntryPrice;
    
82.             SendOrderThisBar = True;
    
83.             SellShort(TurtleUnits,myEntryPrice);
    
84.                         SendOrderThisBar = True;
    
85.                         PreBreakoutFailure = False;
    
86.         }
    
87.     }
    
88. 
    
89.     // 长周期突破开仓 Failsafe Breakout point
    
90.     If(MarketPosition == 0)
    
91.     {
    
92.                 Commentary("fsDonchianHi="+Text(fsDonchianHi));
    
93.         If(CrossOver(High,fsDonchianHi) && TurtleUnits >= 1)
    
94.         {
    
95.             // 开仓价格取突破上轨+一个价位和最高价之间的较小值，这样能更接近真实情况，并能尽量保证成交
    
96.             myEntryPrice = min(high,fsDonchianHi + MinPoint);
    
97.             myEntryPrice = IIF(myEntryPrice < Open, Open,myEntryPrice); // 大跳空的时候用开盘价代替
    
98.                         preEntryPrice = myEntryPrice;
    
99.             Buy(TurtleUnits,myEntryPrice);
    
100.                         SendOrderThisBar = True;
     
101.                         PreBreakoutFailure = False;
     
102.         }
     
103. 
     
104.                 Commentary("fsDonchianLo="+Text(fsDonchianLo));
     
105.         If(CrossUnder(Low,fsDonchianLo) && TurtleUnits >= 1)
     
106.         {
     
107.             // 开仓价格取突破下轨-一个价位和最低价之间的较大值，这样能更接近真实情况，并能尽量保证成交
     
108.             myEntryPrice = max(low,fsDonchianLo - MinPoint);
     
109.             myEntryPrice = IIF(myEntryPrice > Open, Open,myEntryPrice); // 大跳空的时候用开盘价代替
     
110.             preEntryPrice = myEntryPrice;
     
111.             SellShort(TurtleUnits,myEntryPrice);
     
112.                         SendOrderThisBar = True;
     
113.                         PreBreakoutFailure = False;
     
114.         }
     
115.     }
     
116. 
     
117.     If(MarketPosition == 1) // 有多仓的情况
     
118.     {
     
119.         // 求出持多仓时离市的条件比较值
     
120.         ExitLowestPrice = Lowest(Low[1],teLength);
     
121.                 Commentary("ExitLowestPrice="+Text(ExitLowestPrice));
     
122.         If(Low < ExitLowestPrice)
     
123.         {
     
124.             myExitPrice = max(Low,ExitLowestPrice - MinPoint);
     
125.                         myExitPrice = IIF(myExitPrice > Open, Open,myExitPrice); // 大跳空的时候用开盘价代替
     
126.             Sell(0,myExitPrice);    // 数量用0的情况下将全部平仓
     
127.         }Else
     
128.         {
     
129.             If(preEntryPrice!=InvalidNumeric && TurtleUnits >= 1)
     
130.             {
     
131.                 If(Open >= preEntryPrice + 0.5*N) // 如果开盘就超过设定的1/2N,则直接用开盘价增仓。
     
132.                 {
     
133.                     myEntryPrice = Open;
     
134.                                         preEntryPrice = myEntryPrice;
     
135.                     Buy(TurtleUnits,myEntryPrice);
     
136.                                         SendOrderThisBar = True;
     
137.                 }
     
138. 
     
139.                 while(High >= preEntryPrice + 0.5*N) // 以最高价为标准，判断能进行几次增仓
     
140.                 {
     
141.                     myEntryPrice = preEntryPrice + 0.5 * N;
     
142.                     preEntryPrice = myEntryPrice;
     
143.                     Buy(TurtleUnits,myEntryPrice);
     
144.                                         SendOrderThisBar = True;                                       
     
145.                 }
     
146.             }
     
147.                        
     
148.             // 止损指令
     
149.                         If(Low <= preEntryPrice - 2 * N && SendOrderThisBar == false) // 加仓Bar不止损
     
150.                         {
     
151.                                 myExitPrice = preEntryPrice - 2 * N;
     
152.                                 Sell(0,myExitPrice); // 数量用0的情况下将全部平仓
     
153.                                 PreBreakoutFailure = True;
     
154.                         }
     
155.         }
     
156.     }Else If(MarketPosition ==-1) // 有空仓的情况
     
157.     {
     
158.         // 求出持空仓时离市的条件比较值
     
159.         ExitHighestPrice = Highest(High[1],teLength);
     
160.                 Commentary("ExitHighestPrice="+Text(ExitHighestPrice));
     
161.         If(High > ExitHighestPrice)
     
162.         {
     
163.             myExitPrice = Min(High,ExitHighestPrice + MinPoint);
     
164.                         myExitPrice = IIF(myExitPrice < Open, Open,myExitPrice); // 大跳空的时候用开盘价代替
     
165.             BuyToCover(0,myExitPrice);    // 数量用0的情况下将全部平仓
     
166.         }Else
     
167.         {
     
168.             If(preEntryPrice!=InvalidNumeric && TurtleUnits >= 1)
     
169.             {
     
170.                 If(Open <= preEntryPrice - 0.5*N) // 如果开盘就超过设定的1/2N,则直接用开盘价增仓。
     
171.                 {
     
172.                     myEntryPrice = Open;
     
173.                                         preEntryPrice = myEntryPrice;
     
174.                     SellShort(TurtleUnits,myEntryPrice);
     
175.                                         SendOrderThisBar = True;
     
176.                 }
     
177. 
     
178.                 while(Low <= preEntryPrice - 0.5*N) // 以最低价为标准，判断能进行几次增仓
     
179.                 {
     
180.                     myEntryPrice = preEntryPrice - 0.5 * N;
     
181.                     preEntryPrice = myEntryPrice;
     
182.                     SellShort(TurtleUnits,myEntryPrice);
     
183.                                         SendOrderThisBar = True;
     
184.                 }
     
185.             }
     
186. 
     
187.             // 止损指令
     
188.                         If(High >= preEntryPrice + 2 * N &&SendOrderThisBar==false) // 加仓Bar不止损
     
189.                         {
     
190.                                 myExitPrice = preEntryPrice + 2 * N;
     
191.                                 BuyToCover(0,myExitPrice); // 数量用0的情况下将全部平仓
     
192.                                 PreBreakoutFailure = True;
     
193.                         }
     
194.         }
     
195.     }
     
196. End
     
197. 
     
198. //------------------------------------------------------------------------
     
199. // 编译版本        GS2004.06.12
     
200. // 版权所有        TradeBlazer Software 2003－2008
     
201. // 更改声明        TradeBlazer Software保留对TradeBlazer平
     
202. //                        台每一版本的TradeBlazer公式修改和重写的权利
     
203. //------------------------------------------------------------------------

复制代码

NumericSeries DonchianHi;              // 唐奇安通道上轨，延后1个Bar
    NumericSeries DonchianLo;              // 唐奇安通道下轨，延后1个Bar
    NumericSeries fsDonchianHi;            // 唐奇安通道上轨，延后1个Bar，长周期
    NumericSeries fsDonchianLo;            // 唐奇安通道下轨，延后1个Bar，长周期

这四个变量貌似没必要声明为NumericSeries 吧？只需要声明为Numeric就行了吧？因为没有使用如
DonchianHi[1]的回溯。不知道理解的对不对？

nopain

CrossOver和CrossUnder里面有用到序列的值

小米

不对。必须要用到序列变量。
因为程序里可以看到有穿越的条件用到了这四个数。而 crossover,crossunder这两个穿越函数要求参与计算的数据必须是序列变量。

z7c9

哦，明白。
不过还有个问题，这里有必要使用crossover和crossunder么？
用high>DonchianHi 不就表示当前bar的high大于前4周的最高值了？，这样的话不就能定义成
numeric了？

小米

>或是<只能表达一个大小的关系。而crossover，crossunder表示的是一个穿越的动作。
用穿越来表示条件，更容易清楚的表现出一个序列值从下向上穿越另一序列值的交叉位置

z7c9

>或是
小米 发表于 2010-8-17 14:50

你是想表达开仓穿越那一刻的动作吧，而非high>DonchianHi 的一个时间段。但是你前面有了MarketPosition==0限制了，所以也只可能是一个时间点吧?所以还是没必要用cross？

小米

你再琢磨一下吧.你的理解不对的.marketposition只是开仓时需要判断的条件之一,并不是说marketposition==0就能确定交叉占的.

z7c9

(A). if(marketposition==0 and high>DonchianHi)
和
(B). if(marketposition==0 and cross(high,DonchianHi))
逻辑上不一样么？
当marketposition==0时，第一根满足high>DonchianHi的bar开仓，随后marketposition==1,不会重复进入A逻辑吧？不就是一个点了么？

小米

为什么你没有考虑过marketposition==0时,已经是high>doncianhi,但是却不满足crossover(high,DonchianHi))的情况?

z7c9

为什么你没有考虑过marketposition==0时,已经是high>doncianhi,但是却不满足crossover(high,DonchianHi))的情况?
小米 发表于 2010-8-17 15:34

怎么出现这种情况的？
marketposition==0时，第一个满足high>donchianhi的bar必然满足crossover(high,dongchianhi)吧？后面的是不是满足并不重要了，因为marketposition==1了。

实在不了解，请解释清楚，比如哪种情况会出现你说的现象？