官微精华
查看: 604659|回复: 90

TradeBlazer公式入门教程 [复制链接]

Rank: 10Rank: 10Rank: 10

精华
3
UID
5
积分
22513
帖子
8842
主题
36
阅读权限
200
注册时间
2007-7-20
最后登录
2017-12-15
发表于 2007-8-21 14:44:18 |显示全部楼层
请大家不要在此贴回复,关于该贴的问题请到这里回复,谢谢!


TradeBlazer公式入门教程(1)

Step 1、在开始写公式之前,我们先了解以下基本概念

Bar数据:
公式在进行计算时,都是建立在基本数据源(Bar数据)之上,我们这里所谓的Bar数据,是指商品在不同周期下形成的序列数据,在单独的每个Bar上面包含开盘价、收盘价、最高价、最低价、成交量及时间。期货等品种还有持仓量等数据。所有的Bar按照不同周期组合,并按照时间从先到后进行排列,由此形成为序列数据,整个序列称之为Bar数据。
公式如何执行:
TradeBlazer公式在计算时按照Bar数据的Bar数目,从第一个Bar到最后一个Bar,依次进行计算,如果公式中出现了调用Bar数据函数的,则取出当前Bar的相应值,进行运算。公式执行从上至下,Bar从左到右执行。

Step 2、接下来,我们从TradeBlazer公式的HelloWorld开始
该贴前期已经发过,因此在此只给出链接:
TradeBlazer公式的HelloWorld!

Step 3、建立一个简单的指标:成交量
对于交易开拓者界面不熟悉的朋友可以参看以下帖子:
如何在交易开拓者中编写技术指标?

新建指标简称: MyVol
  1. Begin
  2.         PlotNumeric("Vol",Vol);       
  3. End
复制代码
BeginEnd宣告公式正文的开始和结束,公式语句应该放到Begin 和End之间。
并且总是以";"作为语句结束的标志。
PlotNumeric表示输出一个数值型组成的数组;公式中“”内所引用的是字符串的常量,内容文字即在图表中所输出的技术指标的名称

关于PlotNumeric的使用
函数原形:
    Numeric PlotNumeric(String Name,Numeric Number,Integer Color=-1,Integer BarsBack=0)
参数:
    Name 输出值的名称,不区分大小写;
    Number 输出的数值;
    Color 输出值的显示颜色,默认表示使用属性设置框中的颜色;
    BarsBack 从当前Bar向前回溯的Bar数,默认值为当前Bar。

技术指标属性的设置
在属性里的常规下填写公式的简称、名称、分类以及注释。也可更改参数等设置:
技术指标属性.jpg (35.06 KB, 下载次数: 396)

在“线型”里选择更改技术指标的输出形态,如线条、柱状图、十字图等,并且选择自己爱好的颜色,
以更加个性化的表现形式来迎合您的看盘习惯。
技术指标线型.JPG (19.47 KB, 下载次数: 332)

Rank: 10Rank: 10Rank: 10

精华
20
UID
4
积分
22702
帖子
4802
主题
64
阅读权限
255
注册时间
2007-7-20
最后登录
2017-11-22
发表于 2007-8-21 15:42:19 |显示全部楼层
TradeBlazer公式入门教程(2)
Step 4:
前面我们所建的技术指标MyVol,可以输出成交量,但成交量只能设置为属性所选的一种颜色。如下图:
普通成交量.png (8.75 KB, 下载次数: 329)

很多朋友习惯于看红绿色表示涨跌的成交量。
下面我们来实现带红绿颜色的成交量指标,代码如下:
  1. Begin
  2.     PlotNumeric(“Vol”,Vol,IIf(Close>=Open,Red,Green));
  3. End
复制代码

使用的情形如下:
红绿色成交量.png (9.19 KB, 下载次数: 329)

关于IIF
函数原形:
    Numeric IIF(Bool Conditon,Numeric TrueValue,Numeric FalseValue)
参数:
    Conditon 条件表达式;
    TrueValue 条件为True时的返回值;
    FalseValue 条件为False时的返回值。

针对上面的使用IIF进行成交量颜色指定的脚本, 我们还有另外一种写法:
  1. Begin
  2.     If(Close>=Open)
  3.         PlotNumeric(“Vol”,Vol,Red);
  4.     Else
  5.         PlotNumeric(“Vol”,Vol,Green);
  6. End
复制代码

PlotNumeric由输出的名字来区分是否为同一条线!

关于IF语句
If语句是一个条件语句,当特定的条件满足后执行一部分操作。
语法如下:
If (Condition)
{
  TradeBlazer公式语句;
}
TradeBlazer公式语句是一些语句的组合,如果TradeBlazer公式语句是单条,您可以省略{},二条或者二条以上的语句必须使用{}。

[ 本帖最后由 nopain 于 2007-8-21 15:58 编辑 ]

使用道具 举报

Rank: 10Rank: 10Rank: 10

精华
3
UID
5
积分
22513
帖子
8842
主题
36
阅读权限
200
注册时间
2007-7-20
最后登录
2017-12-15
发表于 2007-8-22 12:16:51 |显示全部楼层
TradeBlazer公式入门教程(3)
Step5

关于条件表达式
   
逻辑操作符
逻辑运算符常常用于比较两个True/False的表达式,共有三个逻辑操作符:AND(&&),OR(||),NOT(!)。   
           
        表达式1 AND 表达式2
        表达式1 OR 表达式2
        NOT表达式1

           如下图表所示可以让大家更清晰地理解逻辑操作符在表达式中的运算结果
未命名111.JPG (42.58 KB, 下载次数: 340)

[ 本帖最后由 小米 于 2007-8-22 12:19 编辑 ]

使用道具 举报

Rank: 10Rank: 10Rank: 10

精华
3
UID
5
积分
22513
帖子
8842
主题
36
阅读权限
200
注册时间
2007-7-20
最后登录
2017-12-15
发表于 2007-8-22 18:36:12 |显示全部楼层
TradeBlazer公式入门教程(4)
Step6

前面第一贴已经讲过了IF语句,接下来要讲解条件语句的另外三种表达方式:
   If-Else
   If-Else-If
   If-Else的嵌套


关于If-Else语句
If-Else语句是对指定条件进行判断,如果条件满足执行If后的语句。否则执行Else后面的语句。

语法如下:
  1. If (Condition)
  2. {
  3.     TradeBlazer公式语句1;
  4. }Else
  5. {
  6.     TradeBlazer公式语句2;
  7. }
复制代码

Condition是一个逻辑表达式,当Condition为True的时候,TradeBlazer公式语句1将会被执行;Condition为False时,TradeBlazer公式语句2将会被执行。Condition可以是多个条件表达式的逻辑组合,Condition必须用()括起来。

TradeBlazer公式语句是一些语句的组合,如果TradeBlazer公式语句是单条,您可以省略{},二条或者二条以上的语句必须使用{}。


例如,比较当前Bar和上一个Bar的收盘价,如果Close > Close[1],Value1 = Value1 + Vol;否则Value1 = Value1 - Vol,脚本如下:
  1. If (Close > Close[1])
  2.     Value1 = Value1 + Vol;
  3. Else
  4.     Value1 = Value1 - Vol;
复制代码




关于If-Else-If的语句
If-Else-If是在If-Else的基础上进行扩展,支持条件的多重分支。

语法如下:

  1. If (Condition1)
  2. {
  3.     TradeBlazer公式语句1;
  4. }Else If(Condition2)
  5. {
  6.     TradeBlazer公式语句2;
  7. }Else
  8. {
  9.     TradeBlazer公式语句3;
  10. }
复制代码


Condition1是一个逻辑表达式,当Condition1为True的时候,TradeBlazer公式语句1将会被执行,Condition1为False时,将会继续判断Condition2的值,当Condition2为True时,TradeBlazer公式语句2将会被执行。Condition2为False时,TradeBlazer公式语句3将会被执行。Condition1,Condition2可以是多个条件表达式的逻辑组合,条件表达式必须用()括起来。

TradeBlazer公式语句是一些语句的组合,如果TradeBlazer公式语句是单条,您可以省略{},二条或者二条以上的语句必须使用{}。

If-Else-If的语句可以根据需要一直扩展,在最后的Else之后再加If(Condition)和新的执行代码即可。当然您也可以省略最后的Else分支,语法如下:

  1. If (Condition1)
  2. {
  3.     TradeBlazer公式语句1;
  4. }Else If(Condition2)
  5. {
  6.     TradeBlazer公式语句2;
  7. }
复制代码




If-Else的嵌套

If-Else的嵌套是在If-Else的执行语句中包含新的条件语句,即一个条件被包含在另一个条件中。

语法如下:

  1. If (Condition1)
  2. {
  3.     If (Condition2)
  4.     {
  5.         TradeBlazer公式语句1;
  6.     }Else
  7.     {
  8.         TradeBlazer公式语句2;
  9.     }
  10. }Else
  11. {
  12.     If (Condition3)
  13.     {
  14.         TradeBlazer公式语句3;
  15.     }Else
  16.     {
  17.         TradeBlazer公式语句4;
  18.     }
  19. }
复制代码



Condition1是一个逻辑表达式,当Condition1为True的时候,将会继续判断Condition2的值,当Condition2为True时,TradeBlazer公式语句1将会被执行。Condition2为False时,TradeBlazer公式语句2将会被执行。当Condition1为False的时候,将会继续判断Condition3的值,当Condition3为True时,TradeBlazer公式语句3将会被执行。Condition3为False时,TradeBlazer公式语句4将会被执行。Condition1,Condition2,Condition3可以是多个条件表达式的逻辑组合,条件表达式必须用()括起来。

TradeBlazer公式语句是一些语句的组合,如果TradeBlazer公式语句是单条,您可以省略{},二条或者二条以上的语句必须使用{}。

例如,在一个交易指令中,条件设置如下:当前行情上涨的时候,如果收盘价高于开盘价时,则产生一个以收盘价买入1张合约;否则产生一个以开盘价买入1张合约。当前行情没有上涨的时候,如果收盘价高于开盘价,则产生一个以收盘价卖出1张合约;否则产生一个以开盘价卖出1张合约。脚本如下:

  1. If (Open > High[1])
  2. {
  3.     If (Close>Open)
  4.     {
  5.         Buy(1,close);
  6.     }Else
  7.     {
  8.         Buy(1,open);
  9.     }
  10. }Else
  11. {
  12.     If (Close > Open)
  13.     {   
  14.         Sell(1,close);
  15.     }Else
  16.     {
  17.         Sell (1,open);
  18.     }
  19. }
复制代码

使用道具 举报

Rank: 10Rank: 10Rank: 10

精华
3
UID
5
积分
22513
帖子
8842
主题
36
阅读权限
200
注册时间
2007-7-20
最后登录
2017-12-15
发表于 2007-8-23 15:33:38 |显示全部楼层
TradeBlazer公式入门教程(5)

Step7


现在再回到成交量指标
有人喜欢在成交量指标上加均线,我们来看如何实现这样的功能。
  1. Begin
  2.     PlotNumeric(“Vol”,Vol);
  3.     PlotNumeric(“AvgVol5”,AverageFC(Vol,5));
  4. End
复制代码


如下图中所示便是加了均线的成交量

avgvol.PNG (11.63 KB, 下载次数: 294)


Step8

关于Average和 AverageFC
Average和AverageFC都是内建的用户函数,目的都是用来求N个Bar以来的平均值,您可以直接看到实现的代码。
如下:
Average
  1. Params
  2.         NumericSeries Price(1);
  3.         Numeric Length(10);
  4. Vars
  5.         Numeric AvgValue;
  6. Begin
  7.         AvgValue = Summation(Price, Length) / Length;        
  8.         Return AvgValue;
  9. End
复制代码


AverageFC
  1. Params
  2.         NumericSeries Price(1);
  3.         Numeric Length(10);
  4. Vars
  5.         Numeric AvgValue;
  6. Begin
  7.         AvgValue = SummationFC(Price, Length) / Length;        
  8.         Return AvgValue;
  9. End
复制代码


Average和AverageFC有什么不同呢?AverageFC是指FastCalculate,即快速计算。当这两个函数的第二个变量,即N个Bar是常量时,使用AverageFC,提高计算效率。当N是不确定的变量时,则必须使用Average,否则会出现计算问题。
单看Average和AverageFC似乎是一样的,唯一不同的是AvgValue的计算方式用到的是Summation和SumamtionFC。



Summation和SumamtionFC
现在再来看看Summation与SumamtionFC的不同之处。公式表达如下:

Summation

  1. Params
  2.         NumericSeries Price(1);
  3.         Numeric Length(10);
  4. Vars
  5.         Numeric SumValue(0);
  6.         Numeric i;
  7. Begin
  8.         If (CurrentBar >= Length-1)
  9.         {
  10.                 for i = 0 to Length - 1
  11.                 {
  12.                         SumValue = SumValue + Price[i];
  13.                 }
  14.         }Else
  15.         {
  16.                 SumValue = InvalidNumeric;
  17.         }
  18.         Return SumValue;
  19. End
复制代码



SummationFC

  1. Params
  2.         NumericSeries Price(1);
  3.         Numeric Length(10);
  4. Vars
  5.         NumericSeries SumValue(0);
  6.         Numeric i;
  7. Begin
  8.         If ( CurrentBar < Length || Price[Length] == InvalidNumeric || SumValue[1] == InvalidNumeric )
  9.         {
  10.                 for i = 0 to Length - 1
  11.                 {
  12.                         SumValue = SumValue + Price[i];
  13.                 }
  14.         }Else
  15.         {
  16.                 SumValue = SumValue[1] + Price - Price[Length] ;
  17.         }
  18.         Return SumValue;
  19. End
复制代码



关于Average函数的参数

Numeric Average(NumericSeries Price, Numeric Length);
Price 需要进行平均的序列变量
Length 平均时回溯的Bar数量

[ 本帖最后由 小米 于 2007-8-24 10:35 编辑 ]

使用道具 举报

Rank: 10Rank: 10Rank: 10

精华
3
UID
5
积分
22513
帖子
8842
主题
36
阅读权限
200
注册时间
2007-7-20
最后登录
2017-12-15
发表于 2007-8-24 15:22:29 |显示全部楼层
TradeBlazer公式入门教程(6)


Step9

接下来我们再说一下常量与变量的定义

常量  
是用来代替一个数或字符串的名称,在公式整个执行过程中不发生改变。

变量
是一个存储值的地址,当变量被声明之后,就可以在脚本中使用变量,可以对其赋值,也可以在其他地方引用变量的值进行计算,要对变量进行操作,直接使用变量名称即可。

变量的主要用处在于它可以存放计算或比较的结果,以方便在之后的脚本中直接引用运算的值,而无需重现计算过程。

例如,我们定义一个变量Y,我们把一个收盘价(Close)乘上8%的所得的值存储在Y中,即Y = Close *8%。那么一旦计算出Close * 8%的值,便赋给变量Y。而无需在公式中输入计算过程,只需调用变量名称即可引用变量的值。

变量有助于程序的优化,这是TradeBlazer公式必须重复调用一些数据,这些数据可能是某些函数(如:Bar数据),或通过表达式执行计算和比较的值。因此,在表达式频繁使用的地方使用变量可提高程序的运行速度和节约内存空间。

使用变量也可以避免输入错误,使程序的可读性提高,示例如下:

未使用变量的公式代码:

  1. If(Close > High[1] + Average(Close,10)*0.5)
  2. {
  3.     Buy(100, High[1] + Average(Close,10)*0.5);
  4. }
复制代码


如果使用变量,则整个代码变得简洁:

  1. Value1 = High[1] + Average(Close,10)*0.5;
  2. If (Close > Value1)
  3. {
  4.     Buy(100,Value1);
  5. }
复制代码


如果一些表达式的组合经常在不同的公式中被调用,这个时候变量就不能实现功能,变量只能在单个公式的内部使用,这个时候我们需要建立用户函数来完成这些功能,详细说明参见用户函数(在TB软件里按F1便会出现联机帮助--公式系统--公式应用--用户函数)

变量类型

TradeBlazer公式支持有三种基本数据类型:数值型(Numeric)、字符串(String)、布尔型(Bool)。为了通过用户函数返回多个值,我们对三种数据类型进行了扩展,增加了引用数据类型。另外,为了对变量,参数进行回溯,我们增加了序列数据类型。因此,我们的数据类型共有九种。但对于变量定义,引用类型是无效的,剩余六种数据类型中分为简单和序列两大类,简单类型变量是单个的值,不能对其进行回溯,序列类型变量是和Bar长度一致的数据排列,我们可以通过回溯来获取当前Bar以前的任意值。

9种数据类型

Bool                 布尔型。
BoolRef            布尔型引用。
BoolSeries         和周期长度一致的Bool型序列值。
Numeric            数值型。
NumericRef       数值型引用。
NumericSeries   和周期长度一致的Numeric型序列值。
String              字符串。
StringRef          字符串引用。
StringSeries      和周期长度一致的String型序列值。


变量声明

在使用变量之前,必须对变量进行声明,TradeBlazer公式使用关键字"Vars"来进行变量宣告,并指定变量类型。可以选择赋默认值,也可以不赋默认值。

变量定义的语法如下:

  1. Vars
  2.     变量类型 变量名1(初值);
  3.     变量类型 变量名2(初值);
  4.     变量类型 变量名3(初值);
复制代码


下面是一些变量定义的例子:

  1. Vars
  2.     NumericSeries   MyVal1(0);              //定义数值型序列变量MyVal1,默认值为0;
  3.     Numeric         MyVal2(0);              //定义数值型变量MyVal2,默认值为0;
  4.     Bool            MyVal3(False);          //定义布尔型变量MyVal3,默认值为False;
  5.     String          MyVal4("Test");         //定义字符串变量MyVal4,默认值为Test。
复制代码


变量定义的个数没有限制,变量名称的命名规范详细说明参见命名规则

整个公式中只能出现一个Vars宣告,并且要放到公式的开始部分,在参数定义之后,正文之前

变量的默认值

在声明变量时,通常会赋给变量一个默认值。例如上例中的0,False,"Test"等就是变量的默认值。如果某个变量没有赋予默认值,系统将会自动给该变量赋予默认值。数值型变量的默认值为0,布尔型变量的默认值为False,字符串的默认值为空串。

变量的默认值是在当公式在执行时,给该变量赋予的初值,使该变量在引用时存在着有效的值。在该公式每个Bar的执行过程中,改变量的默认值都会被重新赋值。


变量赋值

变量声明完成之后,您可以在脚本正文中给变量指定一个值。

语法如下:
  1. Name = Expression;
复制代码



"Name"是变量的名称,表达式的类型可以是数值型、布尔型、字符串中的任何一种。不过表达式的类型一定要和变量的数据类型相匹配。如果变量被指定为是数值型的,那么表达式一定要是数值型的表达式。

例如:下面的语句将Close的10周期平均值赋值给变量Value1:

  1. Value1 = Average(Close , 10);
复制代码


在下面这个语句中,声明了一个名为"KeyReversal"的逻辑型变量,然后又把计算的值赋给它。

  1. Vars
  2.     Bool        KeyReversal(False);
  3. Begin
  4.     KeyReversal = Low < Low[1] AND Close > High[1];
  5.     ...
  6. End
复制代码


变量使用

变量定义、赋值之后,在表达式中直接使用变量名就可以引用变量的值。例如在下面的语句中计算了买入价格后,把值赋给数值型变量EntryPrc,在买入指令中便可直接应用变量名,通过变量名便可引用变量的值:

  1. Vars
  2.     Numeric EntryPrc(0);
  3. Begin
  4.     EntryPrc = Highest(High,10);
  5.     If (MarkerPosition <> 1)
  6.     {
  7.         Buy(1,EntryPrc);
  8.     }
  9. End
复制代码


接下来的例子,我们计算最近10个Bar最高价中的最大值(不包括当前Bar),对比当前High,然后通过If语句,产生报警信息。

  1. Vars
  2.     Bool    Con1(False);
  3. Begin
  4.     Con1 = High > Highest(High[1],10);
  5.     If(Con1)
  6.     {
  7.         Alert("New 10-bar high");
  8.     }
  9. End
复制代码



其实我们并不一定都要应用条件为True的情况,有时候我们需要判断条件为False的时候执行某些代码,如下的例子:

  1. Vars
  2.     Bool    Con1(False);
  3. Begin
  4.     Con1 = High < Highest(High[1],10) AND Low > Lowest(Low[1],10);
  5.     If(Con1==False)
  6.     {
  7.         Alert("New high or low");
  8.     }
  9. End
复制代码



序列变量

  1. Vars
  2.     NumericSeries  MyNumSVal(0);
  3.     BoolSeries          MyBoolVal(False);
  4.     StringSeries          MyStrVal("");
复制代码


序列变量和简单变量一样,可以对其赋予默认值。

序列变量定义之后,您可以象简单变量一样的对其使用,不会有任何的不同。除了支持全部简单变量的功能之外,序列变量还可以通过"[nOffset]"来回溯以前的变量值,详细说明参见变量回溯

对于序列变量,TradeBlazer公式在内部针对其回溯的特性作了很多的特殊处理,也需要为序列变量保存相应的历史数据,因此,和简单变量相比,执行的速度和占用内存空间方面都作了一些牺牲。因此,尽管您可以定义一个序列变量,把它当作简单变量来使用,但是,我们强烈建议您只将需要进行回溯的变量定义为序列变量。

成交量指标的扩充

回到成交量指标上,在成交量和均线的基础上再增加输出一条线,显示成交量和5日均线的差值。

  1. Params
  2.     Numeric Length(5);
  3. Begin
  4.     PlotNumeric(“Vol”,Vol);
  5.     PlotNumeric(“AvgVol”,AverageFC(Vol, Length));
  6.     PlotNumeric(“VolDiff”,Vol-AverageFC(Vol,Length));
  7. End
复制代码


这样的写法效率较低,因此我们引入变量来进行处理。

对成交量指标的优化

我们通过使用变量来使代码变得简洁,并提高执行效率。上面的公式修改如下:

  1. Params
  2.     Numeric Length(5);
  3. Vars
  4.     Numeric AvgVol5;
  5. Begin
  6.     AvgVol5 = AverageFC(Vol, Length);
  7.     PlotNumeric("Vol",Vol);
  8.     PlotNumeric("AvgVol",AvgVol5);
  9.     PlotNumeric("VolDiff",Vol- AvgVol5);
  10. End
复制代码



如下图所示是增加了差值的成交量:
voldiff3.png (17.66 KB, 下载次数: 312)

使用道具 举报

Rank: 10Rank: 10Rank: 10

精华
3
UID
5
积分
22513
帖子
8842
主题
36
阅读权限
200
注册时间
2007-7-20
最后登录
2017-12-15
发表于 2007-8-27 10:24:02 |显示全部楼层
TradeBlazer公式入门教程(7)


Step10


回到加均线的成交量指标
刚才的成交量指标输出的5周期均线,有的人希望使用10周期均线,为了方便使用,我们使用参数来处理这种需求。
  1. Params
  2.     Numeric Length(5);
  3. Begin
  4.     PlotNumeric(“Vol”,Vol);
  5.     PlotNumeric(“AvgVol”,AverageFC(Vol, Length));
  6. End
复制代码
在上述公式中只要将参数Numeric Length后面的数值(5)改成(10)便可以啦。

关于参数

参数

参数是一个预先声明的地址,用来存放输入参数的值,在声明之后,您就可以在接下来的公式中使用该参数的名称来引用其值。

参数的值在公式的内部是不能够被修改,在整个程序中一直保持不变,不能对参数进行赋值操作(引用参数是个特例)。参数的好处在于您可以在调用执行技术分析,交易指令的时候才指定相应的参数,而不需要重新编译。

例如,我们常用的移动平均线指标,就是通过不同的Length来控制移动平均线的周期,在调用指标时可以随意修改各个Length的值,使之能够计算出相对应的移动平均线。您可以指定4个参数为5,10,20,30计算出这4条移动平均线,也可以修改4个参数为10,22,100,250计算出另外的4条移动平均线。

参数的修改很简单,在超级图表调用指标的过程中,您可以打开指标的属性设置框,切换到参数页面,手动修改各项参数的值,然后应用即可(如下图),交易开拓者将根据新的参数设置计算出新的结果,在超级图表中反映出来。

avgvol2.PNG (12.22 KB, 下载次数: 264)

另外,参数的一个额外的优点是,我们可以通过修改交易指令不同的参数,计算交易指令组合的优劣,达到优化参数的目的。


参数类型

在介绍参数类型之前,我们需要对于TradeBlazer公式的六种类型作一些说明,用户函数是六种公式中比较特殊的一类,它自身不能被超级图表,行情报价这样的模块调用,只能被其他五类公式或者用户函数调用,因此它的参数类型也和其他几种不一样。

用户函数的参数类型可以包含TradeBlazer公式的九种类型,而其他五类公式只能使用三种简单的基本类型。

三种简单类型参数通过传值的方式将参数值传入公式,公式内部通过使用参数名称,将参数值用来进行计算或赋值。

引用参数是在调用的时候传入一个变量的地址,在用户函数内部会修改参数的值,在函数执行完毕,上层调用的公式会通过变量获得修改后的值,引用参数对于需要通过用户函数返回多个值的情况非常有用。

序列参数可以通过回溯获取以前Bar的值,具体介绍可参见参数回溯

参数声明

在使用参数之前,必须对参数进行声明,TradeBlazer公式使用关键字"Params"来进行参数宣告,并指定参数类型。可以选择赋默认值,也可以不赋默认值。如果某个参数没有赋予默认值,则这个参数之前的其他参数的默认值都将被忽略。

参数定义的语法如下:
  1. Params
  2.     参数类型 参数名1(初值);
  3.     参数类型 参数名2(初值);
  4.     参数类型 参数名3(初值);
复制代码
下面是一些参数的例子:
  1. Params
  2.     Bool            bTest(False);       //定义布尔型参数bTest,默认值为False;
  3.     Numeric        Length(10);         //定义数值型参数Length,默认值为10;
  4.     NumericSeries   Price(0);           //定义数值型序列参数Price,默认值为0;
  5.     NumericRef      output(0);          //定义数值型引用参数output,默认值为0;
  6.     String          strTmp("Hello");    //定义字符串参数strTmp,默认值为Hello;
复制代码
参数名称的命名规范详细说明参见命名规则

整个公式中只能出现一个Params宣告,并且要放到公式的开始部分,在变量定义之前

参数的默认值

在声明参数时,通常会赋给参数一个默认值。例如上例中的False,10,0等就是参数的默认值。用户函数的默认值是在当用户函数被其他公式调用,省略参数时作为参数的输入值,其他五种公式的默认值是用于图表,报价等模块调用公式时默认的输入值。

参数的默认值的类型在定义的时候指定,默认值在公式调用的时候传入作为参数进行计算。只能够对排列在后面的那些参数提供默认参数,例如:
  1. Params
  2.     Numeric        MyVal1;
  3.     Numeric        MyVal2(0);
  4.     Numeric        MyVal3(0);
复制代码
不能够使用以下方式对参数的默认值进行设定:
  1. Params
  2.     Numeric        MyVal1(0);
  3.     Numeric        MyVal2(0);
  4.     Numeric        MyVal3;
复制代码
参数的使用

在声明参数之后,我们可以在脚本正文中通过参数名称使用该参数,在使用的过程中要注意保持数据类型的匹配,示例如下:
  1. Params
  2.     NumericSeries Price(1);
  3. Vars
  4.     NumericSeriss CumValue(0);
  5. Begin
  6.     CumValue = CumValue[1] + Price;       
  7.     Return CumValue;
  8. End
复制代码
在以上的公式中,首先定义了一个数值型序列参数Price,并将其默认值设置为1。接着定义了一个变量CumValue。脚本正文中,将CumValue的上一个Bar值加上Price,并将值赋给CumValue,最后返回CumValue。

通过上述的公式可以看到,我们只需要调用参数名,就可以使用参数的值进行计算了,如果要对序列参数进行回溯,请参见参数回溯

引用参数


TradeBlazer公式的用户函数可以通过返回值,返回函数的计算结果,返回值只能是三种简单类型。当我们需要通过函数进行计算,返回多个值的时候,单个的返回值就不能满足需求了。在这种情况下,我们提出了引用参数的概念,引用参数是在调用的时候传入一个变量的地址,在用户函数内部会修改参数的值,在函数执行完毕,上层调用的公式会通过变量获得修改后的值。因为引用参数的使用是没有个数限制,因此,我们可以通过引用参数返回任意多个值。

例如,用户函数MyFunc如下:
  1. Params
  2.     NumericSeries   Price(0);
  3.     NumericRef      oHigher(0);
  4.     NumericRef      oLower(0);
  5. Vars
  6.     Numeric         Tmp(0);
  7. Begin
  8.     Tmp = Average(Price,10);
  9.     oHigher = IIf(Tmp > High,Tmp,High);
  10.     oLower = IIf(Tmp < Low,Tmp,Low);
  11.     Return Tmp;
  12. End
复制代码
以上代码通过两个数值型引用参数返回10个周期的Price平均值和最高价的较大值oHigher,以及10个周期的Price平均值和最低价的较小值oLower,并且通过函数返回值输出10个周期的Price平均值。在调用该用户函数的公式中,可以通过调用该函数获得3个计算返回值,示例如下:
  1. Vars
  2.     Numeric AvgValue;
  3.     Numeric HigherValue;
  4.     Numeric LowerValue;
  5. Begin
  6.     AvgValue = MyFunc(Close,HigherValue,LowerValue);
  7.     ...
  8. End
复制代码

使用道具 举报

Rank: 10Rank: 10Rank: 10

精华
3
UID
5
积分
22513
帖子
8842
主题
36
阅读权限
200
注册时间
2007-7-20
最后登录
2017-12-15
发表于 2007-8-29 16:02:31 |显示全部楼层
TradeBlazer公式入门教程(8)

Step11

创建稍复杂的指标

我们以MACD指标为例,介绍一般指标的写法。

MACD的技术指标包含参数,变量和正文三部分。
如下所示:


MACD输出4条线。包括线条和变色柱状线及零线。

macd.PNG (17.09 KB, 下载次数: 339)

使用道具 举报

Rank: 10Rank: 10Rank: 10

精华
3
UID
5
积分
22513
帖子
8842
主题
36
阅读权限
200
注册时间
2007-7-20
最后登录
2017-12-15
发表于 2007-8-29 17:47:42 |显示全部楼层
TradeBlazer公式入门教程(9)

Step12


关于价差指标-Spread

如何进行商品叠加?
交易开拓者的超级图表支持商品叠加的显示,当叠加的图表调用各项公式时,可能有需要使用叠加的商品对应的基础数据,针对这样的需求,TradeBlazer公式提供了叠加数据的支持。详细请参照贴子如何在超级图表中叠加商品,并进行价差运算

价差指标的公式代码

下面我们就举一个简单例子,两个商品以收盘价来计算的价差:

  1. Begin
  2.         If(Data0.Close != InvalidNumeric && Data1.Close != InvalidNumeric)
  3.         {
  4.                 PlotNumeric("Spread",Data0.Close - Data1.Close);
  5.         }
  6. End
复制代码


有些人习惯将价差作为K线形式表现出来,如下图所示:

spread.PNG (19.82 KB, 下载次数: 312)

图中蓝线就代表了两个商品收盘价的价差


关于在价差基础上扩展出的SpreadEX

有些人还习惯于将不同商品的开盘价、收盘价、最高价以及最低价的价差再集中体现在同一图表上,如下例:

  1. Begin
  2.        If(Data0.Close !=InvalidNumeric && Data1.Close != InvalidNumeric0
  3.        {
  4.                     PlotNumeric("Open", Data0.Open - Data1.Open);
  5.                     PlotNumeric("Close", Data0.Close - Data1.Close);
  6.                     PlotNumeric("High", max(Data0.High - Data1.High,Data0.Low - Data1.Low);
  7.                     PlotNumeric("Low", min(Data0.High - Data1.High,Data0.Low - Data1.Low));
  8.         }
  9. End
复制代码


最后这四个指标在两个商品中的价差得到的K线图示如下:

spreadEX.PNG (20.63 KB, 下载次数: 325)

使用道具 举报

Rank: 10Rank: 10Rank: 10

精华
3
UID
5
积分
22513
帖子
8842
主题
36
阅读权限
200
注册时间
2007-7-20
最后登录
2017-12-15
发表于 2007-8-30 10:46:20 |显示全部楼层
TradeBlazer公式入门教程(10)


Step13

数据回溯

在TradeBlazer公式中有三种类型的数据回溯:变量回溯、参数回溯和函数回溯

如何使用回溯表达? XXX[nOffset]

nOffset是要回溯引用的Bar相对于当前Bar的偏移值,该值必须大于等于0,当nOffset = 0时,即为获取当前Bar的参数值。并且nOffset不能大于当时的CurrentBar,这样会导致数据访问越界。造成不可预知的计算结果。

变量回溯

TradeBlazer公式共支持九种数据类型,但对于变量定义,引用类型是无效的,剩余六种数据类型中分为简单和序列两大类,简单类型变量是单个的值,不能对其进行回溯,序列类型变量是和Bar长度一致的数据排列,我们可以通过回溯来获取当前Bar以前的任意值。

要使用变量回溯,需要在变量的后面,使用中括号"[nOffset]",nOffset是要回溯引用的Bar相对于当前Bar的偏移值,该值必须大于等于0,当nOffset = 0时,即为获取当前Bar的变量值。

例如,我们定义如下技术指标:

  1. Vars
  2.     NumericSeries MyVal;
  3. Begin
  4.     MyVal = Average(Close,10);
  5.     PlotNumeric("MyVal",MyVal[3]);
  6. End
复制代码


以上公式定义数值型序列变量MyVal,MyVal等于收盘价的10个周期的平均值,然后将序列变量MyVal的前3个Bar数据输出。

以上公式MyVal的前9个数据因为需要计算的Bar数据不足,返回无效值,从第10个Bar开始,MyVal获取到正确的平均值,但是我们需要输出的数据是MyVal[3],即前3个Bar的数据,因此,直到第12个Bar,有效的数据才会被输出。以上公式的12是该公式需要的最少引用周期数,如果将输出信息画到超级图表中,前11个Bar是没有图形显示的。

当nOffset>CurrentBar或者nOffset<0时,对于变量的回溯都将越界,这种情况下,将返回无效值。


参数回溯

TradeBlazer公式支持的九种基本类型,在用户函数的参数定义中全部支持,在其他的公式中参数定义只支持三种简单类型。因此,关于参数的回溯问题,只对用户函数有效,以下我们举例说明用户函数序列参数的使用。

要使用参数回溯,需要在参数的后面,使用中括号"[nOffset]",nOffset是要回溯引用的Bar相对于当前Bar的偏移值,该值必须大于等于0,当nOffset = 0时,即为获取当前Bar的参数值。

例如,我们定义一个用户函数MyFunc,脚本如下:

  1. Params
  2.     NumericSeries   Price(0);
  3.     Numeric         Length(10);
  4. Vars
  5.     Numeric         MyAvg;
  6.     Numeric         MyDeviation;
  7. Begin
  8.     MyAvg = Summation(Price,Length)/Length;
  9.     MyDeviation = MyAvg - Price[Length];
  10.     Return MyDeviation;
  11. End
复制代码


以上的例子,对输入的Price我们求其10个周期的平均值,然后求出该平均值和Price的前Length个Bar的值之间的差值,将其返回。对于Price[Length]这样的参数回溯引用,其实现原理和上节所描述的变量回溯引用基本一致。


函数回溯

函数回溯分为系统函数的回溯和用户函数的回溯。

系统函数中回溯的使用主要是针对Bar数据。比如我们需要获取上2个Bar的收盘价,脚本为Close[2];又或者我们需要获取10个Bar前的成交量,脚本为Vol[10]。对于Bar数据的回溯是系统函数中最常用的,虽然也可以对行情数据和交易数据等进行回溯,但是大部分并无实质的意义,返回的结果和不回溯是一样的,因此,不推荐如此使用。

要对函数回溯引用,我们可以通过在函数名称后面添加"[nOffset]"获取其回溯值,nOffset是要回溯引用的Bar相对于当前Bar的偏移值,该值必须大于等于0,当nOffset = 0时,即为获取当前Bar的参数值。

带有参数的函数回溯,需要将"[nOffset]"放到参数之后,另外,无参数和使用默认参数的情况下,函数调用的括号可以省略。例如:Close[2]等同于Close()[2]。

用户函数的回溯和系统函数原理基本一致,但考虑到系统的执行速度和效率等因素,目前,TradeBlazer公式不支持对用户函数的回溯,如果您想要获取用户函数的回溯值,建议您将函数返回值赋值给一个序列变量,通过对序列变量的回溯来达到相同的目的。

如下面的脚本所示,取Close的10个Bar平均值的4个周期前的回溯值:

  1. Vars
  2.     NumericSeries AvgValue;
  3.     Numeric       TmpValue;
  4. Begin   
  5.     AvgValue = Average(Close,10);
  6.     TmpValue = AvgValue[4];
  7.     ...
  8. End
复制代码

[ 本帖最后由 小米 于 2007-8-30 10:48 编辑 ]

使用道具 举报

您需要登录后才可以回帖 登录 | 注册

bottom

静态版|手机版|联系我们|交易开拓者 ( 粤ICP备07044698   

GMT+8, 2017-12-17 19:36

Powered by Discuz! X2 LicensedChrome插件扩展

© 2011-2012 交易开拓者 Inc.

回顶部