我从文华转到TB的过程(我也圈一个地啊)

sandboy2005

Params
    NumericSeries Price(1);
Vars
    Numeric CumValue(0);
Begin
    CumValue = CumValue[1] + Price;       
    Return CumValue;
End

sandboy2005

交易函数
AvgBarsEvenTrade: 获得保本交易的平均持仓Bar数。

AvgBarsLosTrade: 获得亏损交易的平均持仓Bar数。

AvgBarsWinTrade: 获得盈利交易的平均持仓Bar数。

AvgEntryPrice: 获得当前持仓的平均建仓价格。

BarsSinceEntry: 获得当前持仓的第一个建仓位置到当前位置的Bar计数。

BarsSinceExit: 获得最近平仓位置到当前位置的Bar计数。

Buy: 产生一个多头建仓操作。

BuyToCover: 产生一个空头平仓操作。

ContractProfit: 获得当前持仓位置的每手浮动盈亏。

CurrentCapital: 获得当前的可用资金。

CurrentContracts: 获得当前持仓的持仓合约数。

CurrentEntries: 获得当前持仓的建仓次数。

EntryDate: 获得当前持仓的第一个建仓位置的日期。

EntryPrice: 获得当前持仓的第一个建仓价格。

EntryTime: 获得当前持仓的第一个建仓位置的时间。

ExitDate: 获得最近平仓位置Bar日期。

ExitPrice: 获得最近平仓位置的平仓价格。

ExitTime: 获得最近平仓位置Bar时间。

GrossLoss: 获得累计的总亏损。

GrossProfit: 获得累计的总利润。

LargestLosTrade: 获得最大单次交易亏损数。

LargestWinTrade: 获得最大单次交易盈利数。

MarketPosition: 获得当前持仓状态。

MaxConsecLosers: 获得最大连续亏损交易次数。

MaxConsecWinners: 获得最大连续盈利交易次数。

MaxContracts: 获得当前持仓的最大持仓合约数。

MaxContractsHeld: 获得最大的持仓合约数

MaxEntries: 获得最大的建仓次数。

MaxIDDrawDown: 获得最大的资产缩水值。

MaxPositionLoss: 获得当前持仓的最大浮动亏损数。

MaxPositionProfit: 获得当前持仓的最大浮动盈利数。

NetProfit: 获得累计的净利润。

NumEvenTrades: 获得保本交易的总次数。

NumLosTrades: 获得亏损交易的总次数。

NumWinTrades: 获得盈利交易的总次数。

PercentProfit: 获得盈利的成功率。

PositionProfit: 获得当前持仓位置的浮动盈亏。

Sell: 产生一个多头平仓操作。

SellShort: 产生一个空头建仓操作。

SetBreakEven: 根据参数进行保本平仓操作。

SetDollarTrailing: 根据参数进行价值回落平仓操作。

SetExitOnClose: 当日收盘全部平仓。

SetInactivate: 根据参数进行盘整平仓操作。

SetPercentTrailing: 根据参数进行百分比回落平仓操作。

SetPeriodTrailing: 根据参数进行区间回落平仓操作。

SetProfitTarget: 根据参数进行获利平仓操作。

SetStopLoss: 根据参数进行止损平仓操作。

TotalBarsEvenTrades: 获得保本交易的总持仓Bar数。

TotalBarsLosTrades: 获得亏损交易的总持仓Bar数。

TotalBarsWinTrades: 获得盈利交易的总持仓Bar数。

TotalTrades: 获得交易的总次数。

sandboy2005

用上面的东东组建你的策略吧！！又回到大学年代的样子

sandboy2005

一个文华交易系统的移植例子


多空趋势-交易系统之文华的公式脚本：

[Copy to clipboard] [ - ]CODE:
MA1:=EMA(CLOSE,16);
MA2:=EMA(CLOSE,35),COLORYELLOW;
MA3:=EMA(CLOSE,60);
MA4:=REF(HIGH,1);

LOWV:=LLV(LOW,9);
HIGHV:=HHV(HIGH,9);

RSV:=EMA((CLOSE-LOWV)/(HIGHV-LOWV)*100,3);
K:=EMA(RSV,3);
D:=MA(K,3);
MV5:=MA(VOL,5);
KK:=REF(K,1);
PP:=REF(LOW,1);

VAR3:=(2*CLOSE+HIGH+LOW)/4;
VAR4:=LLV(LOW,33);
VAR5:=HHV(HIGH,33);
ZL:=EMA((VAR3-VAR4)/(VAR5-VAR4)*100,17);
SH:=EMA(0.667*REF(ZL,1)+0.333*ZL,2);
LC:=REF(CLOSE,1);
RSI:=SMA(MAX(CLOSE-LC, 0), 6, 1)/SMA(ABS(CLOSE-LC), 6, 1)*100;

CROSS(CLOSE,MA1)&&(K>D)&&(ZL>SH)||CROSS(MA1,MA2)&&(ZL>SH)&&(VOL>1.25*MV5)&&(K>D)||CROSS(K,D)&&(CLOSE>MA1)&&(ZL>SH)||CROSS(RSI,70),BK;
CROSS(PP,CLOSE)&&(D>K)&&(SH>ZL)||CROSS(D,K)&&(CLOSE<MA1)&&(MA1<MA2)||CROSS(KK,K)&&(SH>ZL),SK;
CROSS(D,K)||(CLOSE<MA1*1.001),SP;
CROSS(K,D)||(CLOSE>MA1*1.001),BP;
TradeBlazer公式代码：

[Copy to clipboard] [ - ]CODE:
//------------------------------------------------------------------------
// 简称: Test
// 名称: 多空趋势交易系统
// 类别: 交易指令
// 类型: 其他
// 输出:
//------------------------------------------------------------------------
Params
        Numeric Length1(16);
        Numeric Length2(35);
        Numeric Length3(9);
        Numeric Lots(1);
Vars
        NumericSeries Value1;
        NumericSeries Value2;
        Numeric LowestValue;
        NumericSeries Value5;
        NumericSeries RSV;
        NumericSeries KValue;
        NumericSeries DValue;
        Numeric AvgVol5;
        NumericSeries CloseTmp1;
        NumericSeries CloseTmp2;
        NumericSeries RSIValue;
        NumericSeries PreLow;
        NumericSeries PreKValue;
        Numeric Lowest33Value;
        NumericSeries VarTmp1;
        NumericSeries VarTmp2;
        NumericSeries ZL;
        Numeric SH;
Begin
        Value1 = XAverage(Close,Length1);
        Value2 = XAverage(Close,Length2);
        //取两条均线的值
        LowestValue = Lowest(Low,Length3);
        //取最低值
        Value5 = (CLOSE-LowestValue)/(Highest(High,Length3)-LowestValue)*100;
        RSV = XAverage(Value5,3);
        KValue = XAverage(RSV,3);
        DValue = Average(KValue,3);
        PreKValue = KValue[1];
        PreLow = Low[1];
        AvgVol5 = Average(Vol,5);
        Lowest33Value = Lowest(Low,33);
        VarTmp1 =((2*CLOSE+HIGH+LOW)/4 - Lowest33Value )/(Highest(High,33) - Lowest33Value) * 100;
        ZL = XAverage(VarTmp1,17);
        VarTmp2 = 0.667*ZL[1] + 0.333*ZL;
        SH = XAverage(VarTmp2,2);
        CloseTmp1 = Max(Close - Close[1], 0);
        CloseTmp2 = Abs(Close - Close[1]);
        RSIValue = WAverage(CloseTmp1,6)/WAverage(CloseTmp2,6) *100;
//以上为KD部分只要如何换书写方式就可了，，higest ==hhv lowest==llv   xAverager=ma      
        // Buy什么时做买入动作，条件
        If( (CrossOver(Close,Value1 ) && (KValue > DValue) && (ZL>SH)) Or
             (CrossOver(Value1,Value2) && (ZL>SH) && (Vol > 1.25 * AvgVol5) && (KValue > DValue)) Or
             (CrossOver(KValue,DValue) && (Close > Value1) && (ZL>SH)) Or
             (CrossOver(RSIValue,70)))//条件
        {
                Buy(Lots,Close);
        }
        
        // SellShort 什么作卖出动作
        If( (CrossOver(PreLow,Close) && (KValue > DValue ) && (SH>ZL) ) Or
             (CrossOver(DValue,KValue) && (Close < Value1) && (Value1 < Value2)) Or
             (CrossOver(PreKValue,KValue)&& (SH>ZL)))//条件
        {
                SellShort(Lots,Close);
        }
        
        // Sell 什么做多平动作
        If(CrossOver(DValue,KValue) || Close < Value1 * 1.001)//条件
        {
                Sell;
        }
        
        // BuyToCover什么进个做空平动作
        If(CrossOver(KValue,DValue) || Close > Value1 * 1.001)//条件
        {
                BuyToCover;
        }
End

//------------------------------------------------------------------------
// 编译版本        GS2004.06.12
// 用户版本        2007-06-25 10:37
// 版权所有        TradeBlazer
// 更改声明        TradeBlazer Software保留对TradeBlazer平台
//                        每一版本的TrabeBlazer公式修改和重写的权利
//------------------------------------------------------------------------

[ 本帖最后由 sandboy2005 于 2007-10-7 14:26 编辑 ]

sandboy2005

交易策略
通常单个交易指令只完成建仓或平仓的单个动作，而一个完整的交易策略应该至少包含建仓、平仓交易指令，并且根据需要加上止损，获利等锁定风险和收益的交易指令。多个交易指令的组合才能更加有效的帮助我们完整的进行交易，因此，我们将多个交易指令的有效组合称之为交易策略。

假定我们创建一个交易策略，该交易策略由以下交易指令组成，并按照如下顺序应用到超级图表中。




当我们将该交易策略应用到超级图表上时，TradeBlazer公式将会从图表的第一个Bar开始执行交易策略，在第一个Bar上首先执行多头建仓指令A，可能会产生交易委托（开仓），该委托可能被设置为在当前Bar执行，也可以被设置为延迟到下一个Bar执行。当多头建仓指令A执行完成之后，将按顺序调用多头平仓指令B，同时该指令会判断当前的持仓状态，仓位等信息，当条件满足的时候会产生交易委托（平仓）。依次执行止损平仓指令C和获利平仓指令D，当四个交易指令在第一个Bar上都执行完之后，将会移到第二个Bar执行，这时候，系统会首先读取上一个Bar是否有延迟的交易委托，如果有延迟的交易委托，对这些委托先进行处理，然后像第一个Bar一样，依次调用各个交易指令。以此类推，从图表的第一个Bar到最后一个Bar，全部执行完成之后，整个交易策略执行完毕。在整个执行过程产生的所有交易委托被保存下来供超级图表模块显示或进行性能测试分析。

sandboy2005

这样大家可以即时交流看法了

sandboy2005

要是打算根据3日的高低价平仓呢?想法如下

想实现这样一个一个想法：价格突破5天最高价，开多仓，把当天和前一天的K线做比较，取两日的最低价格做为止损，当价格突破3日最低价时，平多仓。
价格突破5日最低价，开空仓，把今天和 ...
你看看哦，代码大致如此：

Params
vars
NumericSeries EntryHi;               
NumericSeries EntryLo;               
NumericSeries ShortStop;            
NumericSeries LongStop;
NumericSeries SellHi;
NumericSeries SellLo;               
Numeric myEntryPrice;                  
Numeric myExitPrice;                    
begin
//入场点，开多和开空点，突破5天最高或最低
EntryHi = Highest(high[1],5);
EntryLo  = Lowest(low[1],5);
//离场点，止盈点，三天较高或较低
SellHi=Highest(high[1],3);
SellLo= Lowest(low[1],3);
//止损点，两天较高或较低
ShortStop= Highest(high[1],2);
LongStop=Lowest(low[1],2);


if(MarketPosition ==0)
{
        If(CrossOver(high,EntryHi))
        {
            
     

            myEntryPrice = min(high,EntryHi );
            myEntryPrice = IIF(myEntryPrice < Open, Open,myEntryPrice);  
            Buy(0,myEntryPrice);
            
        }

        If(CrossUnder(Low,EntryLo ))
        {


            myEntryPrice = max(low,EntryLo  );
            myEntryPrice = IIF(myEntryPrice > Open, Open,myEntryPrice);  
            SellShort(0,myEntryPrice);
  
        }
}
               

        
If(MarketPosition ==1)
{
           if (CrossUnder(Low,LongStop))
           {

            myExitPrice = max(low,LongStop );
            myExitPrice = IIF(myExitPrice > Open, Open,myExitPrice);
               
                        Sell(0,myExitPrice);
                }Else

           if (CrossUnder(Low,SellLo))
           {
                myExitPrice = max(low,SellLo );
            myExitPrice = IIF(myExitPrice > Open, Open,myExitPrice);
                        Sell(0,myExitPrice);
       }


}
               
If(MarketPosition ==-1)
{
           if (CrossOver(high,ShortStop))
           {
                  myExitPrice = min(high,ShortStop );
          myExitPrice = IIF(myExitPrice < Open, Open,myExitPrice);
         
                        BuyToCover(0,myExitPrice);
                }Else

       if (CrossOver(high,SellHi))
           {
                  myExitPrice = min(high,SellHi );  
                  myExitPrice = IIF(myExitPrice < Open, Open,myExitPrice);
         
                        BuyToCover(0,myExitPrice);
                }



}
        
end

[ 本帖最后由 sandboy2005 于 2007-10-7 16:50 编辑 ]

skywalker

合着您这圈块地，开博客呢

pwqzc

严重支持!!!

mht88

严重学习!